Как настроить точку доступа (AP) ESP32 для веб-сервера
ESP32 может работать как Wi-Fi станция, как точка доступа или в обоих режимах одновременно. В этом руководстве мы покажем вам, как настроить ESP32 в режиме точки доступа с помощью Arduino IDE.
В большинстве проектов с ESP32 мы подключаем ESP32 к беспроводному роутеру (смотрите наше руководство по веб-серверу ESP32). Таким образом мы можем получить доступ к ESP32 через локальную сеть.
В этом случае роутер выступает в роли точки доступа, а ESP32 настроен как станция. В таком сценарии вам необходимо быть подключенным к вашему роутеру (локальной сети) для управления ESP32.
Но если вы настроите ESP32 как точку доступа (хотспот), вы сможете подключиться к ESP32, используя любое устройство с поддержкой Wi-Fi, без необходимости подключения к роутеру.
Простыми словами, когда вы настраиваете ESP32 как точку доступа, вы создаете собственную Wi-Fi сеть, и ближайшие Wi-Fi устройства (станции) могут к ней подключаться (например, ваш смартфон или компьютер).
Здесь мы покажем вам, как настроить ESP32 в качестве точки доступа в ваших проектах веб-серверов. Таким образом, вам не нужно быть подключенным к роутеру для управления ESP32. Поскольку ESP32 не подключается далее к проводной сети (например, к вашему роутеру), это называется soft-AP (программная точка доступа).
Установка платы ESP32 в Arduino IDE
Существует дополнение для Arduino IDE, которое позволяет программировать ESP32 с использованием Arduino IDE и его языка программирования. Следуйте одному из следующих руководств для подготовки вашей Arduino IDE:
Точка доступа ESP32
В этом примере мы модифицируем веб-сервер ESP32 из предыдущего руководства, чтобы добавить возможности точки доступа. То, что мы покажем здесь, может быть использовано с любым примером веб-сервера ESP32.
Загрузите приведенный ниже скетч, чтобы настроить ESP32 как точку доступа.
/*********
Rui Santos
Complete project details at https://randomnerdtutorials.com
*********/
// Load Wi-Fi library
#include <WiFi.h>
// Replace with your network credentials
const char* ssid = "ESP32-Access-Point";
const char* password = "123456789";
// Set web server port number to 80
WiFiServer server(80);
// Variable to store the HTTP request
String header;
// Auxiliar variables to store the current output state
String output26State = "off";
String output27State = "off";
// Assign output variables to GPIO pins
const int output26 = 26;
const int output27 = 27;
void setup() {
Serial.begin(115200);
// Initialize the output variables as outputs
pinMode(output26, OUTPUT);
pinMode(output27, OUTPUT);
// Set outputs to LOW
digitalWrite(output26, LOW);
digitalWrite(output27, LOW);
// Connect to Wi-Fi network with SSID and password
Serial.print("Setting AP (Access Point)…");
// Remove the password parameter, if you want the AP (Access Point) to be open
WiFi.softAP(ssid, password);
IPAddress IP = WiFi.softAPIP();
Serial.print("AP IP address: ");
Serial.println(IP);
server.begin();
}
void loop(){
WiFiClient client = server.available(); // Listen for incoming clients
if (client) { // If a new client connects,
Serial.println("New Client."); // print a message out in the serial port
String currentLine = ""; // make a String to hold incoming data from the client
while (client.connected()) { // loop while the client's connected
if (client.available()) { // if there's bytes to read from the client,
char c = client.read(); // read a byte, then
Serial.write(c); // print it out the serial monitor
header += c;
if (c == '\n') { // if the byte is a newline character
// if the current line is blank, you got two newline characters in a row.
// that's the end of the client HTTP request, so send a response:
if (currentLine.length() == 0) {
// HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
// and a content-type so the client knows what's coming, then a blank line:
client.println("HTTP/1.1 200 OK");
client.println("Content-type:text/html");
client.println("Connection: close");
client.println();
// turns the GPIOs on and off
if (header.indexOf("GET /26/on") >= 0) {
Serial.println("GPIO 26 on");
output26State = "on";
digitalWrite(output26, HIGH);
} else if (header.indexOf("GET /26/off") >= 0) {
Serial.println("GPIO 26 off");
output26State = "off";
digitalWrite(output26, LOW);
} else if (header.indexOf("GET /27/on") >= 0) {
Serial.println("GPIO 27 on");
output27State = "on";
digitalWrite(output27, HIGH);
} else if (header.indexOf("GET /27/off") >= 0) {
Serial.println("GPIO 27 off");
output27State = "off";
digitalWrite(output27, LOW);
}
// Display the HTML web page
client.println("<!DOCTYPE html><html>");
client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
client.println("<link rel=\"icon\" href=\"data:,\">");
// CSS to style the on/off buttons
// Feel free to change the background-color and font-size attributes to fit your preferences
client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
client.println(".button { background-color: #4CAF50; border: none; color: white; padding: 16px 40px;");
client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
client.println(".button2 {background-color: #555555;}</style></head>");
// Web Page Heading
client.println("<body><h1>ESP32 Web Server</h1>");
// Display current state, and ON/OFF buttons for GPIO 26
client.println("<p>GPIO 26 - State " + output26State + "</p>");
// If the output26State is off, it displays the ON button
if (output26State=="off") {
client.println("<p><a href=\"/26/on\"><button class=\"button\">ON</button></a></p>");
} else {
client.println("<p><a href=\"/26/off\"><button class=\"button button2\">OFF</button></a></p>");
}
// Display current state, and ON/OFF buttons for GPIO 27
client.println("<p>GPIO 27 - State " + output27State + "</p>");
// If the output27State is off, it displays the ON button
if (output27State=="off") {
client.println("<p><a href=\"/27/on\"><button class=\"button\">ON</button></a></p>");
} else {
client.println("<p><a href=\"/27/off\"><button class=\"button button2\">OFF</button></a></p>");
}
client.println("</body></html>");
// The HTTP response ends with another blank line
client.println();
// Break out of the while loop
break;
} else { // if you got a newline, then clear currentLine
currentLine = "";
}
} else if (c != '\r') { // if you got anything else but a carriage return character,
currentLine += c; // add it to the end of the currentLine
}
}
}
// Clear the header variable
header = "";
// Close the connection
client.stop();
Serial.println("Client disconnected.");
Serial.println("");
}
}
Настройка SSID и пароля
Вам нужно задать имя SSID и пароль для доступа к ESP32. В этом примере мы устанавливаем имя SSID ESP32 как ESP32-Access-Point, но вы можете изменить имя на любое другое. Пароль – 123456789, но вы также можете его изменить.
// You can customize the SSID name and change the password
const char* ssid = "ESP32-Access-Point";
const char* password = "123456789";
Настройка ESP32 как точки доступа
В функции setup() есть раздел для настройки ESP32 в качестве точки доступа с помощью метода softAP():
WiFi.softAP(ssid, password);
Существуют также другие необязательные параметры, которые можно передать методу softAP(). Вот все параметры:
.softAP(const char* ssid, const char* password, int channel, int ssid_hidden, int max_connection)
SSID (определен ранее): максимум 63 символа;
password (определен ранее): минимум 8 символов; установите NULL, если хотите, чтобы точка доступа была открытой
channel: номер Wi-Fi канала (1-13)
ssid_hidden: (0 = транслировать SSID, 1 = скрыть SSID)
max_connection: максимальное количество одновременно подключенных клиентов (1-4)
Далее нам нужно получить IP-адрес точки доступа с помощью метода softAPIP() и вывести его в монитор порта.
IPAddress IP = WiFi.softAPIP();
Serial.print("AP IP address: ");
Serial.println(IP);
Это фрагменты кода, которые необходимо включить в ваши скетчи веб-сервера для настройки ESP32 в качестве точки доступа. Чтобы узнать, как работает полный код веб-сервера, ознакомьтесь с руководством по веб-серверу ESP32.
Необходимые компоненты
Для этого руководства вам понадобятся следующие компоненты:
Вы можете воспользоваться приведенными выше ссылками или перейти непосредственно на MakerAdvisor.com/tools, чтобы найти все компоненты для ваших проектов по лучшей цене!
Схема
Начните со сборки схемы. Подключите два светодиода к ESP32, как показано на следующей принципиальной схеме – один светодиод подключен к GPIO 26, а другой к GPIO 27.
Примечание: Мы используем плату ESP32 DEVKIT DOIT с 36 выводами. Перед сборкой схемы убедитесь, что вы проверили распиновку используемой вами платы.
IP-адрес ESP32
Загрузите код в ваш ESP32 (убедитесь, что выбрана правильная плата и COM-порт). Откройте монитор порта на скорости 115200 бод. Нажмите кнопку «Enable» на ESP32.
IP-адрес, который вам нужен для доступа к точке ESP32, будет выведен. В данном случае это 192.168.4.1.
Подключение к точке доступа ESP32
Когда ESP32 запущен с новым скетчем, на вашем смартфоне откройте настройки Wi-Fi и нажмите на сеть ESP32-Access-Point:
Введите пароль, который вы определили ранее в коде.
Откройте веб-браузер и введите IP-адрес 192.168.4.1. Должна загрузиться страница веб-сервера:
Для подключения к точке доступа на вашем компьютере перейдите в настройки сети и интернета и выберите «ESP32-Access-Point».
Введите пароль, который вы определили ранее.
Готово! Теперь, чтобы получить доступ к странице веб-сервера ESP32, вам достаточно ввести IP-адрес ESP32 в вашем браузере.
Заключение
Это простое руководство показало вам, как настроить ESP32 в качестве точки доступа в ваших скетчах веб-серверов. Когда ESP32 настроен как точка доступа, устройства с поддержкой Wi-Fi могут подключаться непосредственно к ESP32 без необходимости подключения к роутеру.
Вам также может быть интересно:
Источник: How to Set an ESP32 Access Point (AP) for Web Server