ESP32: Статический/фиксированный IP-адрес

В этом руководстве показано, как установить статический/фиксированный IP-адрес для вашей платы ESP32. Если вы запускаете веб-сервер или Wi-Fi клиент на ESP32 и каждый раз при перезагрузке платы она получает новый IP-адрес, вы можете следовать этому руководству, чтобы назначить статический/фиксированный IP-адрес.

Скетч для статического/фиксированного IP-адреса

Чтобы показать вам, как зафиксировать IP-адрес ESP32, мы будем использовать код веб-сервера ESP32 в качестве примера. К концу нашего объяснения вы сможете зафиксировать IP-адрес независимо от того, какой веб-сервер или Wi-Fi проект вы создаёте.

Скопируйте приведённый ниже код в вашу Arduino IDE, но пока не загружайте его. Вам нужно внести некоторые изменения, чтобы он работал у вас.

Примечание

Если вы загрузите следующий скетч на вашу плату ESP32, он автоматически назначит фиксированный IP-адрес 192.168.1.184.

/*********
  Rui Santos
  Complete project details at https://randomnerdtutorials.com
*********/

// Load Wi-Fi library
#include <WiFi.h>

// Replace with your network credentials
const char* ssid     = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";

// Set web server port number to 80
WiFiServer server(80);

// Variable to store the HTTP request
String header;

// Auxiliar variables to store the current output state
String output26State = "off";
String output27State = "off";

// Assign output variables to GPIO pins
const int output26 = 26;
const int output27 = 27;

// Set your Static IP address
IPAddress local_IP(192, 168, 1, 184);
// Set your Gateway IP address
IPAddress gateway(192, 168, 1, 1);

IPAddress subnet(255, 255, 0, 0);
IPAddress primaryDNS(8, 8, 8, 8);   //optional
IPAddress secondaryDNS(8, 8, 4, 4); //optional

void setup() {
  Serial.begin(115200);
  // Initialize the output variables as outputs
  pinMode(output26, OUTPUT);
  pinMode(output27, OUTPUT);
  // Set outputs to LOW
  digitalWrite(output26, LOW);
  digitalWrite(output27, LOW);

  // Configures static IP address
  if (!WiFi.config(local_IP, gateway, subnet, primaryDNS, secondaryDNS)) {
    Serial.println("STA Failed to configure");
  }

  // Connect to Wi-Fi network with SSID and password
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  // Print local IP address and start web server
  Serial.println("");
  Serial.println("WiFi connected.");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  server.begin();
}

void loop(){
  WiFiClient client = server.available();   // Listen for incoming clients

  if (client) {                             // If a new client connects,
    Serial.println("New Client.");          // print a message out in the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    while (client.connected()) {            // loop while the client's connected
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        header += c;
        if (c == '\n') {                    // if the byte is a newline character
          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println("Connection: close");
            client.println();

            // turns the GPIOs on and off
            if (header.indexOf("GET /26/on") >= 0) {
              Serial.println("GPIO 26 on");
              output26State = "on";
              digitalWrite(output26, HIGH);
            } else if (header.indexOf("GET /26/off") >= 0) {
              Serial.println("GPIO 26 off");
              output26State = "off";
              digitalWrite(output26, LOW);
            } else if (header.indexOf("GET /27/on") >= 0) {
              Serial.println("GPIO 27 on");
              output27State = "on";
              digitalWrite(output27, HIGH);
            } else if (header.indexOf("GET /27/off") >= 0) {
              Serial.println("GPIO 27 off");
              output27State = "off";
              digitalWrite(output27, LOW);
            }

            // Display the HTML web page
            client.println("<!DOCTYPE html><html>");
            client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
            client.println("<link rel=\"icon\" href=\"data:,\">");
            // CSS to style the on/off buttons
            // Feel free to change the background-color and font-size attributes to fit your preferences
            client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
            client.println(".button { background-color: #4CAF50; border: none; color: white; padding: 16px 40px;");
            client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
            client.println(".button2 {background-color: #555555;}</style></head>");

            // Web Page Heading
            client.println("<body><h1>ESP32 Web Server</h1>");

            // Display current state, and ON/OFF buttons for GPIO 26
            client.println("<p>GPIO 26 - State " + output26State + "</p>");
            // If the output26State is off, it displays the ON button
            if (output26State=="off") {
              client.println("<p><a href=\"/26/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/26/off\"><button class=\"button button2\">OFF</button></a></p>");
            }

            // Display current state, and ON/OFF buttons for GPIO 27
            client.println("<p>GPIO 27 - State " + output27State + "</p>");
            // If the output27State is off, it displays the ON button
            if (output27State=="off") {
              client.println("<p><a href=\"/27/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/27/off\"><button class=\"button button2\">OFF</button></a></p>");
            }
            client.println("</body></html>");

            // The HTTP response ends with another blank line
            client.println();
            // Break out of the while loop
            break;
          } else { // if you got a newline, then clear currentLine
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }
      }
    }
    // Clear the header variable
    header = "";
    // Close the connection
    client.stop();
    Serial.println("Client disconnected.");
    Serial.println("");
  }
}

Посмотреть исходный код

Настройка сетевых учётных данных

Вам нужно изменить следующие строки, указав ваши сетевые учётные данные: SSID и пароль.

// Replace with your network credentials
const char* ssid = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";

Установка статического IP-адреса

Затем, вне функций setup() и loop(), вы определяете следующие переменные с вашим собственным статическим IP-адресом и соответствующим IP-адресом шлюза.

По умолчанию следующий код назначает IP-адрес 192.168.1.184, который работает со шлюзом 192.168.1.1.

// Set your Static IP address
IPAddress local_IP(192, 168, 1, 184);
// Set your Gateway IP address
IPAddress gateway(192, 168, 1, 1);

IPAddress subnet(255, 255, 0, 0);
IPAddress primaryDNS(8, 8, 8, 8); // optional
IPAddress secondaryDNS(8, 8, 4, 4); // optional

Важно

Вам нужно использовать свободный IP-адрес в вашей локальной сети и соответствующий шлюз.

setup()

В функции setup() вам нужно вызвать метод WiFi.config() для назначения конфигурации вашему ESP32.

// Configures static IP address
if (!WiFi.config(local_IP, gateway, subnet, primaryDNS, secondaryDNS)) {
  Serial.println("STA Failed to configure");
}

Примечание

Параметры primaryDNS и secondaryDNS являются необязательными, и вы можете их убрать.

Тестирование

После загрузки кода на плату откройте монитор порта Arduino IDE на скорости 115200 бод, перезагрузите плату ESP32, и ранее определённый IP-адрес должен быть назначен вашей плате.

Как видите, он выводит IP-адрес 192.168.1.184.

Вы можете взять этот пример и добавить его во все ваши Wi-Fi скетчи для назначения фиксированного IP-адреса вашему ESP32.

Назначение IP-адреса через MAC-адрес

Если вы попробовали назначить фиксированный IP-адрес ESP32 с помощью предыдущего примера и это не сработало, мы рекомендуем назначить IP-адрес непосредственно в настройках вашего роутера через MAC-адрес ESP32.

Добавьте ваши сетевые учётные данные (SSID и пароль). Затем загрузите следующий код на ваш ESP32:

/*********
  Rui Santos
  Complete project details at https://randomnerdtutorials.com
*********/

// Load Wi-Fi library
#include <WiFi.h>

// Replace with your network credentials
const char* ssid     = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";

// Set web server port number to 80
WiFiServer server(80);

void setup() {
  Serial.begin(115200);

  // Connect to Wi-Fi network with SSID and password
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  // Print local IP address and start web server
  Serial.println("");
  Serial.println("WiFi connected.");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  server.begin();

  // Print ESP MAC Address
  Serial.println("MAC address: ");
  Serial.println(WiFi.macAddress());
}

void loop() {
  // put your main code here, to run repeatedly:
}

Посмотреть исходный код

В функции setup(), после подключения к сети, код выводит MAC-адрес ESP32 в монитор порта:

// Print ESP MAC Address
Serial.println("MAC address: ");
Serial.println(WiFi.macAddress());

В нашем случае MAC-адрес ESP32 – B4:E6:2D:97:EE:F1. Скопируйте MAC-адрес, потому что он понадобится вам через мгновение.

Настройки роутера

Если вы войдёте в административную панель вашего роутера, там должна быть страница/меню, где вы можете назначить IP-адрес сетевому устройству. Каждый роутер имеет различные меню и конфигурации. Поэтому мы не можем предоставить инструкции о том, как это сделать для всех доступных роутеров.

Мы рекомендуем поискать в Google «назначить IP-адрес MAC-адресу» (или «assign IP address to MAC address»), добавив название вашего роутера. Вы должны найти инструкции, показывающие, как назначить IP MAC-адресу для вашего конкретного роутера.

В итоге, если вы перейдёте в меню конфигурации вашего роутера, вы сможете назначить желаемый IP-адрес MAC-адресу вашего ESP32 (например, B4:E6:2D:97:EE:F1).

Заключение

После выполнения этого руководства вы должны уметь назначать фиксированный/статический IP-адрес вашему ESP32.

Надеемся, что это руководство было для вас полезным. Если вам интересен ESP32, вам также могут понравиться:

• Изучение ESP32 с Arduino IDE

• Начало работы с платой ESP32

• Справочник по выводам ESP32: какие GPIO использовать?

• 200+ проектов и руководств по электронике

Спасибо за чтение.

---

Источник: ESP32 Static/Fixed IP Address