Arduino UNO R4 Minima — Часы реального времени

Узнайте, как получить доступ к часам реального времени (RTC) на UNO R4 Minima.

В этом руководстве вы узнаете, как получить доступ к часам реального времени (RTC) на плате Arduino UNO R4 Minima. RTC встроены в микроконтроллер UNO R4 Minima (RA4M1).

Цели

Цели этого проекта:

Установить начальную дату RTC
Получить дату/время из RTC в календарном формате.
Получить время в формате Unix.

Необходимое оборудование и программное обеспечение

Часы реального времени (RTC)

Доступ к RTC на UNO R4 Minima можно получить с помощью библиотеки RTC, которая входит в состав пакета плат UNO R4. Эта библиотека позволяет устанавливать/получать время, а также использовать будильники для запуска прерываний.

Существует множество практических примеров использования RTC, и примеры, представленные на этой странице, помогут вам начать работу с ним.

Установка времени

RTCTime startTime(30, Month::JUNE, 2023, 13, 37, 00, DayOfWeek::WEDNESDAY, SaveLight::SAVING_TIME_ACTIVE)
RTC.setTime(startTime)

Чтобы установить начальное время для RTC, вы можете создать объект RTCTime. Здесь вы можете указать день, месяц, год, час, минуту, секунду, а также указать день недели и режим летнего времени.

Затем, чтобы установить время, используйте метод setTime().

Пример:

#include "RTC.h"

void setup() {
  Serial.begin(9600);

  RTC.begin();

  RTCTime startTime(30, Month::JUNE, 2023, 13, 37, 00, DayOfWeek::WEDNESDAY, SaveLight::SAVING_TIME_ACTIVE);

  RTC.setTime(startTime);
}

void loop(){
}

Получение времени

RTC.getTime(currentTime)

Чтобы получить время, нам нужно создать объект RTCTime и использовать метод getTime() для получения текущего времени.

Этот пример устанавливает и получает время и сохраняет его в объекте RTCTime с именем currentTime.

#include "RTC.h"

void setup() {
  Serial.begin(9600);

  RTC.begin();

  RTCTime startTime(30, Month::JUNE, 2023, 13, 37, 00, DayOfWeek::WEDNESDAY, SaveLight::SAVING_TIME_ACTIVE);

  RTC.setTime(startTime);
}

void loop(){
RTCTime currentTime;

// Get current time from RTC
RTC.getTime(currentTime);
}

Вывод даты и времени

Приведённые выше примеры показывают, как установить и получить время и сохранить его в объекте. Эти данные можно извлечь с помощью ряда методов:

getDayOfMonth()
getMonth()
getYear()
getHour()
getMinutes()
getSeconds()

Приведённый ниже пример выводит дату и время из объекта currentTime.

#include "RTC.h"

void setup() {
  Serial.begin(9600);

  RTC.begin();

  RTCTime startTime(30, Month::JUNE, 2023, 13, 37, 00, DayOfWeek::WEDNESDAY, SaveLight::SAVING_TIME_ACTIVE);

  RTC.setTime(startTime);
}

void loop() {
  RTCTime currentTime;

  // Get current time from RTC
  RTC.getTime(currentTime);

  // Print out date (DD/MM//YYYY)
  Serial.print(currentTime.getDayOfMonth());
  Serial.print("/");
  Serial.print(Month2int(currentTime.getMonth()));
  Serial.print("/");
  Serial.print(currentTime.getYear());
  Serial.print(" - ");

  // Print time (HH/MM/SS)
  Serial.print(currentTime.getHour());
  Serial.print(":");
  Serial.print(currentTime.getMinutes());
  Serial.print(":");
  Serial.println(currentTime.getSeconds());

  delay(1000);
}

Unix

currentTime.getUnixTime()

Чтобы получить временную метку Unix, используйте метод getUnixTime().

#include "RTC.h"

void setup() {
  Serial.begin(9600);

  RTC.begin();

  RTCTime startTime(30, Month::JUNE, 2023, 13, 37, 00, DayOfWeek::WEDNESDAY, SaveLight::SAVING_TIME_ACTIVE);

  RTC.setTime(startTime);
}

void loop() {
  RTCTime currentTime;

  // Get current time from RTC
  RTC.getTime(currentTime);

  //Unix timestamp
  Serial.print("Unix timestamp: ");
  Serial.println(currentTime.getUnixTime());

  delay(1000);
}

Периодическое прерывание

Периодическое прерывание позволяет задать повторяющийся обратный вызов (callback).

Для его использования необходимо инициализировать периодический обратный вызов с помощью метода setPeriodicCallback():

RTC.setPeriodicCallback(periodic_cbk, Period::ONCE_EVERY_2_SEC)

Также необходимо создать функцию, которая будет вызываться:

void periodicCallback() { код для выполнения }

Примечание

Обратите внимание, что IRQ имеет очень быстрое время выполнения. Размещение большого количества кода — не лучшая практика, поэтому в приведённом ниже примере мы переключаем только один флаг irqFlag.

Приведённый ниже пример мигает светодиодом каждые 2 секунды:

#include "RTC.h"

volatile bool irqFlag = false;
volatile bool ledState = false;

const int led = LED_BUILTIN;

void setup() {
  pinMode(led, OUTPUT);

  Serial.begin(9600);

  // Initialize the RTC
  RTC.begin();

  // RTC.setTime() must be called for RTC.setPeriodicCallback to work, but it doesn't matter
  // what date and time it's set to
  RTCTime mytime(30, Month::JUNE, 2023, 13, 37, 00, DayOfWeek::WEDNESDAY, SaveLight::SAVING_TIME_ACTIVE);
  RTC.setTime(mytime);

  if (!RTC.setPeriodicCallback(periodicCallback, Period::ONCE_EVERY_2_SEC)) {
    Serial.println("ERROR: periodic callback not set");
  }
}

void loop(){
  if(irqFlag){
    Serial.println("Timed CallBack");
    ledState = !ledState;
    digitalWrite(LED_BUILTIN, ledState);
    irqFlag = false;
  }
}

void periodicCallback()
{
  irqFlag = true;
}

Период можно указать с помощью следующих перечислений:

ONCE_EVERY_2_SEC
ONCE_EVERY_1_SEC
N2_TIMES_EVERY_SEC
N4_TIMES_EVERY_SEC
N8_TIMES_EVERY_SEC
N16_TIMES_EVERY_SEC
N32_TIMES_EVERY_SEC
N64_TIMES_EVERY_SEC
N128_TIMES_EVERY_SEC
N256_TIMES_EVERY_SEC

Обратный вызов по будильнику

RTC.setAlarmCallback(alarm_cbk, alarmtime, am)

unsigned long previousMillis = 0;
const long interval = 1000;
bool ledState = false;

// Include the RTC library
#include "RTC.h"

void setup() {
  //initialize Serial Communication
  Serial.begin(9600);

  //define LED as output
  pinMode(LED_BUILTIN, OUTPUT);

  // Initialize the RTC
  RTC.begin();

  // RTC.setTime() must be called for RTC.setAlarmCallback to work, but it doesn't matter
  // what date and time it's set to in this example
  RTCTime initialTime(7, Month::JUNE, 2023, 13, 03, 00, DayOfWeek::WEDNESDAY, SaveLight::SAVING_TIME_ACTIVE);
  RTC.setTime(initialTime);

  // Trigger the alarm every time the seconds are zero
  RTCTime alarmTime;
  alarmTime.setSecond(0);

  // Make sure to only match on the seconds in this example - not on any other parts of the date/time
  AlarmMatch matchTime;
  matchTime.addMatchSecond();

  //sets the alarm callback
  RTC.setAlarmCallback(alarmCallback, alarmTime, matchTime);
}

void loop() {

  // in the loop, we continuously print the alarm's current state
  // this is for debugging only and has no effect on the alarm whatsoever
  unsigned long currentMillis = millis();
  if (currentMillis - previousMillis >= interval) {
    // save the last time you blinked the LED
    previousMillis = currentMillis;
    Serial.print("Alarm state: ");
    Serial.println(ledState);
  }
}

// this function activates every minute
// and changes the ledState boolean
void alarmCallback() {
  if (!ledState) {
    digitalWrite(LED_BUILTIN, HIGH);
  } else {
    digitalWrite(LED_BUILTIN, LOW);
  }
  ledState = !ledState;
}

Итоги

В этом руководстве показано, как использовать RTC на UNO R4 Minima: установка начального времени, настройка будильника, получение времени в календарном формате или формате Unix.

Подробнее об этой плате читайте в документации Arduino UNO R4 Minima.