HC-05 FC-114 и HC-06 FC-114. Часть 2 — Основные AT-команды

Примечание

Обновление 19.09.2015

У плат FC-114, которые есть у автора, установлена прошивка Bolutek. Пользователь DS сообщил, что у него FC-114 с прошивкой linvorV1.8. Если описанное ниже не работает, проверьте, какая прошивка установлена на вашем модуле.

Поскольку модули HC-05 FC-114 и HC-06 FC-114 используют одну и ту же прошивку, нижеописанное должно работать на обоих модулях.

Настройка по умолчанию при запуске — режим Slave (ведомый), ожидание сопряжения или подключения, а также приём AT-команд. Это означает, что начать использовать AT-команды довольно просто.

Подключение

Подключение аналогично другим модулям HC-05 и HC-06:

• Arduino D2 к BT TX

• Arduino D3 к делителю напряжения, затем к BT RX

• Arduino 5V к BT VCC

• GND к GND

Скетч HC-0x_FC-114_01_9600

После выполнения подключения загрузите следующий скетч. Скетч принимает всё, что введено в монитор порта, и отправляет на Bluetooth-модуль. Он также копирует всё, что получено от Bluetooth-модуля, в монитор порта. Кроме того, он дублирует пользовательский ввод в главное окно монитора порта.

// Basic bluetooth test sketch. HC-0x_FC-114_01_9600
//  Uses hardware serial to talk to the host computer and software serial for communication with the bluetooth module
//
//  Pins
//  BT VCC to Arduino 5V out.
//  BT GND to GND
//  Arduino D3 to BT RX through a voltage divider
//  Arduino D2 BT TX (no need voltage divider)
//
//  When a command is entered in the serial monitor on the computer
//  the Arduino will relay it to the bluetooth module and display the result.
//
// The HC-0x FC-114 modules require CR and NL

#include <SoftwareSerial.h>
SoftwareSerial BTSerial(2, 3); // RX | TX

char c = ' ';
boolean NL = true;

void setup()
{
      Serial.begin(9600);
      Serial.println("Sketch HC-0x_FC-114_01_9600");
      Serial.println("Arduino with HC-0x FC-114 is ready");
      Serial.println("Make sure Both NL & CR are set");
      Serial.println("");

      // FC-114 default baud rate is 9600
      BTSerial.begin(9600);
      Serial.println("BTserial started at 9600");
      Serial.println("");

}

void loop()
{

    // Read from the Bluetooth module and send to the Arduino Serial Monitor
    if (BTSerial.available())
    {
        c = BTSerial.read();
        Serial.write(c);
    }

    // Read from the Serial Monitor and send to the Bluetooth module
    if (Serial.available())
    {
        c = Serial.read();
        BTSerial.write(c);

        // Echo the user input to the main window. The ">" character indicates the user entered text.
        if (NL) { Serial.print(">");  NL = false; }
        Serial.write(c);
        if (c==10) { NL = true; }
    }

}

После загрузки откройте монитор порта, и вы должны увидеть следующее:

Чтобы убедиться, что AT-команды работают, введите AT и нажмите «Отправить».

Вы также можете проверить версию прошивки с помощью AT+VERSION:

Модули автора сообщают версию прошивки как:

+BOLUTEK Firmware V2.43, Bluetooth V2.0, HCI V2.1, HCI Rev37, LMP V4, LMP SubV37

Чтобы получить список доступных AT-команд, введите AT+HELP и нажмите «Отправить»:

Вот и всё, что нужно для начала работы.

Для получения более подробной информации об AT-командах ознакомьтесь с руководством пользователя BLK-MD-BC04-B по AT-командам.