Telegram: ESP32-CAM — съёмка и отправка фото (Arduino IDE)

В этом руководстве вы создадите Telegram-бота для взаимодействия с ESP32-CAM, чтобы запрашивать новые фотографии. Вы можете запросить новое фото из своей учётной записи Telegram из любой точки мира. Вам нужен только доступ к интернету на смартфоне.

Примечание

Этот проект совместим с любой платой ESP32 Camera Board с камерой OV2640. Вам просто нужно убедиться, что вы используете правильную распиновку для вашей платы.

Обзор проекта 

Вот обзор проекта, который вы создадите:

Вы создадите Telegram-бота для вашей ESP32-CAM;
Вы сможете начать разговор с ботом ESP32-CAM;
Когда вы отправляете сообщение /photo боту ESP32-CAM, плата ESP32-CAM получает сообщение, делает новое фото и отправляет его в ответ;
Вы можете отправить сообщение /flash для переключения вспышки ESP32-CAM;
Вы можете отправить сообщение /start, чтобы получить приветственное сообщение с командами для управления платой;
ESP32-CAM будет отвечать только на сообщения, приходящие от вашего Telegram User ID.

Это простой проект, но он показывает, как можно использовать Telegram в ваших IoT-проектах и проектах домашней автоматизации. Идея состоит в том, чтобы применить изученные концепции в ваших собственных проектах.

У нас также есть специальный проект для ESP32-CAM с Telegram, который охватывает более продвинутые функции: управление выходами, запрос показаний датчиков и уведомления о движении.

Знакомство с Telegram 

Telegram Messenger — это облачный сервис мгновенного обмена сообщениями и голосовой связи. Вы можете легко установить его на свой смартфон (Android и iPhone) или компьютер (PC, Mac и Linux). Он бесплатный и без рекламы. Telegram позволяет создавать ботов, с которыми можно взаимодействовать.

«Боты — это сторонние приложения, которые работают внутри Telegram. Пользователи могут взаимодействовать с ботами, отправляя им сообщения, команды и встроенные запросы. Вы управляете своими ботами с помощью HTTPS-запросов к Telegram Bot API».

ESP32-CAM будет взаимодействовать с Telegram-ботом для получения и обработки сообщений, а также отправки ответов. В этом руководстве вы узнаете, как использовать Telegram для отправки сообщений вашему боту, чтобы запросить новое фото, сделанное ESP32-CAM. Вы можете получить фото, где бы вы ни находились (вам нужен только Telegram и доступ в интернет).

Создание Telegram-бота 

Перейдите в Google Play или App Store, скачайте и установите Telegram.

Откройте Telegram и выполните следующие шаги для создания Telegram-бота. Сначала найдите «botfather» и нажмите на BotFather, как показано ниже. Или откройте эту ссылку t.me/botfather на своём смартфоне.

Должно открыться следующее окно, и вам будет предложено нажать кнопку start.

Telegram Start BotFather для создания нового бота

Введите /newbot и следуйте инструкциям для создания вашего бота. Дайте ему имя и username.

Если ваш бот успешно создан, вы получите сообщение со ссылкой для доступа к боту и токеном бота. Сохраните токен бота, потому что он понадобится вам, чтобы ESP32 мог взаимодействовать с ботом.

Telegram BotFather получение токена бота

Примечание

Токен бота — это очень длинная строка. Чтобы убедиться, что вы скопировали его правильно, перейдите в веб-интерфейс Telegram и скопируйте токен бота оттуда.

Получение Telegram User ID 

Любой, кто знает username вашего бота, может с ним взаимодействовать. Чтобы убедиться, что мы игнорируем сообщения не из нашей учётной записи Telegram (или любых авторизованных пользователей), вы можете получить свой Telegram User ID. Тогда, когда ваш Telegram-бот получит сообщение, ESP сможет проверить, соответствует ли ID отправителя вашему User ID, и обработать сообщение или проигнорировать его.

В вашей учётной записи Telegram найдите «IDBot» или откройте эту ссылку t.me/myidbot на своём смартфоне.

Telegram получение Chat ID с помощью IDBot

Начните разговор с этим ботом и введите /getid. Вы получите ответ с вашим User ID. Сохраните этот User ID, потому что он понадобится вам далее в этом руководстве.

Telegram получение Chat ID с помощью IDBot getid

Подготовка Arduino IDE 

Мы будем программировать плату ESP32 с помощью Arduino IDE, поэтому убедитесь, что у вас установлена поддержка ESP32 в Arduino IDE.

Установка платы ESP32 в Arduino IDE

Библиотека Universal Telegram Bot

Для взаимодействия с Telegram-ботом мы будем использовать библиотеку Universal Telegram Bot, созданную Brian Lough, которая предоставляет удобный интерфейс для Telegram Bot API.

Выполните следующие шаги для установки последней версии библиотеки:

Нажмите здесь, чтобы скачать библиотеку Universal Arduino Telegram Bot.
Перейдите в Sketch > Include Library > Add .ZIP Library….
Добавьте только что скачанную библиотеку.

Важно

Не устанавливайте библиотеку через Arduino Library Manager, потому что он может установить устаревшую версию.

Для всех подробностей о библиотеке посмотрите страницу Universal Arduino Telegram Bot Library на GitHub.

Библиотека ArduinoJson

Вам также необходимо установить библиотеку ArduinoJson. Выполните следующие шаги для установки библиотеки:

Перейдите в Sketch > Include Library > Manage Libraries.
Найдите «ArduinoJson».
Установите библиотеку.

Мы используем библиотеку ArduinoJson версии 6.15.2.

Установка библиотеки ArduinoJSON в Arduino IDE

Код 

Скопируйте следующий код в Arduino IDE. Чтобы этот скетч работал для вас, вам нужно вставить свои сетевые учётные данные (SSID и пароль), токен Telegram-бота и ваш Telegram User ID. Кроме того, проверьте назначение выводов для используемой вами платы камеры.

/*
  Rui Santos
  Complete project details at https://RandomNerdTutorials.com/telegram-esp32-cam-photo-arduino/

  Permission is hereby granted, free of charge, to any person obtaining a copy
  of this software and associated documentation files.

  The above copyright notice and this permission notice shall be included in all
  copies or substantial portions of the Software.
*/

#include <Arduino.h>
#include <WiFi.h>
#include <WiFiClientSecure.h>
#include "soc/soc.h"
#include "soc/rtc_cntl_reg.h"
#include "esp_camera.h"
#include <UniversalTelegramBot.h>
#include <ArduinoJson.h>

const char* ssid = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";

// Initialize Telegram BOT
String BOTtoken = "XXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX";  // your Bot Token (Get from Botfather)

// Use @myidbot to find out the chat ID of an individual or a group
// Also note that you need to click "start" on a bot before it can
// message you
String CHAT_ID = "XXXXXXXXXX";

bool sendPhoto = false;

WiFiClientSecure clientTCP;
UniversalTelegramBot bot(BOTtoken, clientTCP);

#define FLASH_LED_PIN 4
bool flashState = LOW;

//Checks for new messages every 1 second.
int botRequestDelay = 1000;
unsigned long lastTimeBotRan;

//CAMERA_MODEL_AI_THINKER
#define PWDN_GPIO_NUM     32
#define RESET_GPIO_NUM    -1
#define XCLK_GPIO_NUM      0
#define SIOD_GPIO_NUM     26
#define SIOC_GPIO_NUM     27

#define Y9_GPIO_NUM       35
#define Y8_GPIO_NUM       34
#define Y7_GPIO_NUM       39
#define Y6_GPIO_NUM       36
#define Y5_GPIO_NUM       21
#define Y4_GPIO_NUM       19
#define Y3_GPIO_NUM       18
#define Y2_GPIO_NUM        5
#define VSYNC_GPIO_NUM    25
#define HREF_GPIO_NUM     23
#define PCLK_GPIO_NUM     22

void configInitCamera(){
  camera_config_t config;
  config.ledc_channel = LEDC_CHANNEL_0;
  config.ledc_timer = LEDC_TIMER_0;
  config.pin_d0 = Y2_GPIO_NUM;
  config.pin_d1 = Y3_GPIO_NUM;
  config.pin_d2 = Y4_GPIO_NUM;
  config.pin_d3 = Y5_GPIO_NUM;
  config.pin_d4 = Y6_GPIO_NUM;
  config.pin_d5 = Y7_GPIO_NUM;
  config.pin_d6 = Y8_GPIO_NUM;
  config.pin_d7 = Y9_GPIO_NUM;
  config.pin_xclk = XCLK_GPIO_NUM;
  config.pin_pclk = PCLK_GPIO_NUM;
  config.pin_vsync = VSYNC_GPIO_NUM;
  config.pin_href = HREF_GPIO_NUM;
  config.pin_sccb_sda = SIOD_GPIO_NUM;
  config.pin_sccb_scl = SIOC_GPIO_NUM;
  config.pin_pwdn = PWDN_GPIO_NUM;
  config.pin_reset = RESET_GPIO_NUM;
  config.xclk_freq_hz = 20000000;
  config.pixel_format = PIXFORMAT_JPEG;
  config.grab_mode = CAMERA_GRAB_LATEST;

  //init with high specs to pre-allocate larger buffers
  if(psramFound()){
    config.frame_size = FRAMESIZE_UXGA;
    config.jpeg_quality = 10;  //0-63 lower number means higher quality
    config.fb_count = 1;
  } else {
    config.frame_size = FRAMESIZE_SVGA;
    config.jpeg_quality = 12;  //0-63 lower number means higher quality
    config.fb_count = 1;
  }

  // camera init
  esp_err_t err = esp_camera_init(&config);
  if (err != ESP_OK) {
    Serial.printf("Camera init failed with error 0x%x", err);
    delay(1000);
    ESP.restart();
  }
}

void handleNewMessages(int numNewMessages) {
  Serial.print("Handle New Messages: ");
  Serial.println(numNewMessages);

  for (int i = 0; i < numNewMessages; i++) {
    String chat_id = String(bot.messages[i].chat_id);
    if (chat_id != CHAT_ID){
      bot.sendMessage(chat_id, "Unauthorized user", "");
      continue;
    }

    // Print the received message
    String text = bot.messages[i].text;
    Serial.println(text);

    String from_name = bot.messages[i].from_name;
    if (text == "/start") {
      String welcome = "Welcome , " + from_name + "\n";
      welcome += "Use the following commands to interact with the ESP32-CAM \n";
      welcome += "/photo : takes a new photo\n";
      welcome += "/flash : toggles flash LED \n";
      bot.sendMessage(CHAT_ID, welcome, "");
    }
    if (text == "/flash") {
      flashState = !flashState;
      digitalWrite(FLASH_LED_PIN, flashState);
      Serial.println("Change flash LED state");
    }
    if (text == "/photo") {
      sendPhoto = true;
      Serial.println("New photo request");
    }
  }
}

String sendPhotoTelegram() {
  const char* myDomain = "api.telegram.org";
  String getAll = "";
  String getBody = "";

  //Dispose first picture because of bad quality
  camera_fb_t * fb = NULL;
  fb = esp_camera_fb_get();
  esp_camera_fb_return(fb); // dispose the buffered image

  // Take a new photo
  fb = NULL;
  fb = esp_camera_fb_get();
  if(!fb) {
    Serial.println("Camera capture failed");
    delay(1000);
    ESP.restart();
    return "Camera capture failed";
  }

  Serial.println("Connect to " + String(myDomain));

  if (clientTCP.connect(myDomain, 443)) {
    Serial.println("Connection successful");

    String head = "--RandomNerdTutorials\r\nContent-Disposition: form-data; name=\"chat_id\"; \r\n\r\n" + CHAT_ID + "\r\n--RandomNerdTutorials\r\nContent-Disposition: form-data; name=\"photo\"; filename=\"esp32-cam.jpg\"\r\nContent-Type: image/jpeg\r\n\r\n";
    String tail = "\r\n--RandomNerdTutorials--\r\n";

    size_t imageLen = fb->len;
    size_t extraLen = head.length() + tail.length();
    size_t totalLen = imageLen + extraLen;

    clientTCP.println("POST /bot"+BOTtoken+"/sendPhoto HTTP/1.1");
    clientTCP.println("Host: " + String(myDomain));
    clientTCP.println("Content-Length: " + String(totalLen));
    clientTCP.println("Content-Type: multipart/form-data; boundary=RandomNerdTutorials");
    clientTCP.println();
    clientTCP.print(head);

    uint8_t *fbBuf = fb->buf;
    size_t fbLen = fb->len;
    for (size_t n=0;n<fbLen;n=n+1024) {
      if (n+1024<fbLen) {
        clientTCP.write(fbBuf, 1024);
        fbBuf += 1024;
      }
      else if (fbLen%1024>0) {
        size_t remainder = fbLen%1024;
        clientTCP.write(fbBuf, remainder);
      }
    }

    clientTCP.print(tail);

    esp_camera_fb_return(fb);

    int waitTime = 10000;   // timeout 10 seconds
    long startTimer = millis();
    boolean state = false;

    while ((startTimer + waitTime) > millis()){
      Serial.print(".");
      delay(100);
      while (clientTCP.available()) {
        char c = clientTCP.read();
        if (state==true) getBody += String(c);
        if (c == '\n') {
          if (getAll.length()==0) state=true;
          getAll = "";
        }
        else if (c != '\r')
          getAll += String(c);
        startTimer = millis();
      }
      if (getBody.length()>0) break;
    }
    clientTCP.stop();
    Serial.println(getBody);
  }
  else {
    getBody="Connected to api.telegram.org failed.";
    Serial.println("Connected to api.telegram.org failed.");
  }
  return getBody;
}

void setup(){
  WRITE_PERI_REG(RTC_CNTL_BROWN_OUT_REG, 0);
  // Init Serial Monitor
  Serial.begin(115200);

  // Set LED Flash as output
  pinMode(FLASH_LED_PIN, OUTPUT);
  digitalWrite(FLASH_LED_PIN, flashState);

  // Config and init the camera
  configInitCamera();

  // Connect to Wi-Fi
  WiFi.mode(WIFI_STA);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  clientTCP.setCACert(TELEGRAM_CERTIFICATE_ROOT); // Add root certificate for api.telegram.org
  while (WiFi.status() != WL_CONNECTED) {
    Serial.print(".");
    delay(500);
  }
  Serial.println();
  Serial.print("ESP32-CAM IP Address: ");
  Serial.println(WiFi.localIP());
}

void loop() {
  if (sendPhoto) {
    Serial.println("Preparing photo");
    sendPhotoTelegram();
    sendPhoto = false;
  }
  if (millis() > lastTimeBotRan + botRequestDelay)  {
    int numNewMessages = bot.getUpdates(bot.last_message_received + 1);
    while (numNewMessages) {
      Serial.println("got response");
      handleNewMessages(numNewMessages);
      numNewMessages = bot.getUpdates(bot.last_message_received + 1);
    }
    lastTimeBotRan = millis();
  }
}

Посмотреть исходный код

Как работает код 

В этом разделе объясняется, как работает код. Продолжайте чтение, чтобы узнать, как работает код, или перейдите к разделу «Демонстрация».

Импорт библиотек

Начните с импорта необходимых библиотек.

#include <Arduino.h>
#include <WiFi.h>
#include <WiFiClientSecure.h>
#include "soc/soc.h"
#include "soc/rtc_cntl_reg.h"
#include "esp_camera.h"
#include <UniversalTelegramBot.h>
#include <ArduinoJson.h>

Сетевые учётные данные

Вставьте свои сетевые учётные данные в следующие переменные.

const char* ssid = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";

Telegram User ID

Вставьте свой Chat ID. Тот, который вы получили от IDBot.

String CHAT_ID = "XXXXXXXXXX";

Токен Telegram-бота

Вставьте токен вашего Telegram-бота, полученный от Botfather, в переменную BOTtoken.

String BOTtoken = "XXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX";

Булева переменная sendPhoto указывает, пора ли отправить новое фото в вашу учётную запись Telegram. По умолчанию она установлена в false.

bool sendPhoto = false;

Создайте нового WiFi-клиента с WiFiClientSecure.

WiFiClientSecure clientTCP;

Создайте бота с токеном и клиентом, определёнными ранее.

UniversalTelegramBot bot(BOTtoken, clientTCP);

Создайте переменную для хранения пина вспышки (FLASH_LED_PIN). В ESP32-CAM AI Thinker вспышка подключена к GPIO 4. По умолчанию установите её в LOW.

#define FLASH_LED_PIN 4
bool flashState = LOW;

Переменные botRequestDelay и lastTimeBotRan используются для проверки новых сообщений Telegram каждые x секунд. В данном случае код будет проверять новые сообщения каждую секунду (1000 миллисекунд). Вы можете изменить это время задержки в переменной botRequestDelay.

int botRequestDelay = 1000;
unsigned long lastTimeBotRan;

Инициализация ESP32-CAM

Следующие строки назначают пины ESP32-CAM AI-Thinker. Если вы используете другую модель камеры ESP32, не забудьте изменить распиновку.

//CAMERA_MODEL_AI_THINKER
#define PWDN_GPIO_NUM     32
#define RESET_GPIO_NUM    -1
#define XCLK_GPIO_NUM      0
#define SIOD_GPIO_NUM     26
#define SIOC_GPIO_NUM     27
#define Y9_GPIO_NUM       35
#define Y8_GPIO_NUM       34
#define Y7_GPIO_NUM       39
#define Y6_GPIO_NUM       36
#define Y5_GPIO_NUM       21
#define Y4_GPIO_NUM       19
#define Y3_GPIO_NUM       18
#define Y2_GPIO_NUM        5
#define VSYNC_GPIO_NUM    25
#define HREF_GPIO_NUM     23
#define PCLK_GPIO_NUM     22

Функция configInitCamera() инициализирует камеру ESP32.

void configInitCamera(){
  camera_config_t config;
  config.ledc_channel = LEDC_CHANNEL_0;
  config.ledc_timer = LEDC_TIMER_0;
  config.pin_d0 = Y2_GPIO_NUM;
  config.pin_d1 = Y3_GPIO_NUM;
  config.pin_d2 = Y4_GPIO_NUM;
  config.pin_d3 = Y5_GPIO_NUM;
  config.pin_d4 = Y6_GPIO_NUM;
  config.pin_d5 = Y7_GPIO_NUM;
  config.pin_d6 = Y8_GPIO_NUM;
  config.pin_d7 = Y9_GPIO_NUM;
  config.pin_xclk = XCLK_GPIO_NUM;
  config.pin_pclk = PCLK_GPIO_NUM;
  config.pin_vsync = VSYNC_GPIO_NUM;
  config.pin_href = HREF_GPIO_NUM;
  config.pin_sscb_sda = SIOD_GPIO_NUM;
  config.pin_sscb_scl = SIOC_GPIO_NUM;
  config.pin_pwdn = PWDN_GPIO_NUM;
  config.pin_reset = RESET_GPIO_NUM;
  config.xclk_freq_hz = 20000000;
  config.pixel_format = PIXFORMAT_JPEG;
  config.grab_mode = CAMERA_GRAB_LATEST;

  //init with high specs to pre-allocate larger buffers
  if(psramFound()){
    config.frame_size = FRAMESIZE_UXGA;
    config.jpeg_quality = 10;  //0-63 lower number means higher quality
    config.fb_count = 1;
  } else {
    config.frame_size = FRAMESIZE_SVGA;
    config.jpeg_quality = 12;  //0-63 lower number means higher quality
    config.fb_count = 1;
  }

  // camera init
  esp_err_t err = esp_camera_init(&config);
  if (err != ESP_OK) {
    Serial.printf("Camera init failed with error 0x%x", err);
    delay(1000);
    ESP.restart();
  }
}

handleNewMessages()

Функция handleNewMessages() обрабатывает действия при поступлении новых сообщений.

void handleNewMessages(int numNewMessages) {
  Serial.print("Handle New Messages: ");
  Serial.println(numNewMessages);

Она проверяет доступные сообщения:

for (int i = 0; i < numNewMessages; i++) {

Получает Chat ID для конкретного сообщения и сохраняет его в переменной chat_id. Chat ID определяет, кто отправил сообщение.

String chat_id = String(bot.messages[i].chat_id);

Если chat_id отличается от вашего Chat ID (CHAT_ID), это означает, что кто-то (не вы) отправил сообщение вашему боту. В этом случае сообщение игнорируется и ожидается следующее сообщение.

if (chat_id != CHAT_ID){
  bot.sendMessage(chat_id, "Unauthorized user", "");
  continue;
}

В противном случае это означает, что сообщение отправлено авторизованным пользователем, поэтому мы сохраняем его в переменной text и проверяем его содержимое.

String text = bot.messages[i].text;
Serial.println(text);

Переменная from_name сохраняет имя отправителя.

String from_name = bot.messages[i].from_name;

Если получено сообщение /start, мы отправляем допустимые команды для управления ESP. Это полезно, если вы забыли, какие команды используются для управления вашей платой.

if (text == "/start") {
  String welcome = "Welcome , " + from_name + "\n";
  welcome += "Use the following commands to interact with the ESP32-CAM \n";
  welcome += "/photo : takes a new photo\n";
  welcome += "/flash : toggles flash LED \n";
  bot.sendMessage(CHAT_ID, welcome, "");
}

Отправка сообщения боту очень проста. Вам нужно использовать метод sendMessage() на объекте bot и передать в качестве аргументов Chat ID получателя, сообщение и режим парсинга.

bool sendMessage(String chat_id, String text, String parse_mode = "");

В нашем примере мы отправляем сообщение на ID, сохранённый в переменной CHAT_ID (который соответствует вашему личному Chat ID), и отправляем сообщение, сохранённое в переменной welcome.

bot.sendMessage(CHAT_ID, welcome, "");

Если получено сообщение /flash, инвертируем переменную flashState и обновляем состояние вспышки. Если она была LOW, устанавливаем HIGH. Если была HIGH, устанавливаем LOW.

if (text == "/flash") {
  flashState = !flashState;
  digitalWrite(FLASH_LED_PIN, flashState);
  Serial.println("Change flash LED state");
}

Наконец, если получено сообщение /photo, устанавливаем переменную sendPhoto в true. Затем в loop() проверяется значение переменной sendPhoto и выполняются соответствующие действия.

if (text == "/photo") {
  sendPhoto = true;
  Serial.println("New photo request");
}

sendPhotoTelegram()

Функция sendPhotoTelegram() делает фото с ESP32-CAM.

Примечание

Часто первое фото, сделанное ESP32-CAM, получается некачественным, потому что датчик ещё не настроил баланс белого. Поэтому, чтобы получить хорошее фото, мы отбрасываем первое.

//Dispose first picture because of bad quality
  camera_fb_t * fb = NULL;
  fb = esp_camera_fb_get();
  esp_camera_fb_return(fb); // dispose the buffered image

  // Take a new photo
  fb = NULL;
  fb = esp_camera_fb_get();
  if(!fb) {
    Serial.println("Camera capture failed");
    delay(1000);
    ESP.restart();
    return "Camera capture failed";
  }

Затем выполняется HTTP POST-запрос для отправки фото вашему Telegram-боту.

clientTCP.println("POST /bot"+BOTtoken+"/sendPhoto HTTP/1.1");
clientTCP.println("Host: " + String(myDomain));
clientTCP.println("Content-Length: " + String(totalLen));
clientTCP.println("Content-Type: multipart/form-data; boundary=RandomNerdTutorials");
clientTCP.println();
clientTCP.print(head);

setup()

В setup() инициализируем Serial Monitor.

Serial.begin(115200);

Устанавливаем вспышку как выход и задаём начальное состояние.

pinMode(FLASH_LED_PIN, OUTPUT);
digitalWrite(FLASH_LED_PIN, flashState);

Вызываем функцию configInitCamera() для настройки и инициализации камеры.

configInitCamera();

Подключаем ESP32-CAM к локальной сети.

WiFi.mode(WIFI_STA);
Serial.println();
Serial.print("Connecting to ");
Serial.println(ssid);
WiFi.begin(ssid, password);
while (WiFi.status() != WL_CONNECTED) {
  Serial.print(".");
  delay(500);
}

loop()

В loop() проверяется состояние переменной sendPhoto. Если она равна true, вызывается функция sendPhotoTelegram() для съёмки и отправки фото в вашу учётную запись Telegram.

if (sendPhoto) {
  Serial.println("Preparing photo");
  sendPhotoTelegram();

Когда фото отправлено, переменная sendPhoto устанавливается в false.

sendPhoto = false;

В loop() также проверяются новые сообщения каждую секунду.

if (millis() > lastTimeBotRan + botRequestDelay)  {
  int numNewMessages = bot.getUpdates(bot.last_message_received + 1);
  while (numNewMessages) {
    Serial.println("got response");
    handleNewMessages(numNewMessages);
    numNewMessages = bot.getUpdates(bot.last_message_received + 1);
  }
  lastTimeBotRan = millis();
}

Когда поступает новое сообщение, вызывается функция handleNewMessages().

while (numNewMessages) {
  Serial.println("got response");
  handleNewMessages(numNewMessages);
  numNewMessages = bot.getUpdates(bot.last_message_received + 1);
}

Вот, в общем-то, и всё, как работает код.

Демонстрация 

Загрузите код на плату ESP32-CAM. Не забудьте перейти в Tools > Board и выбрать вашу плату. Перейдите в Tools > Port и выберите COM-порт, к которому подключена ваша плата.

После загрузки кода нажмите кнопку RST на плате ESP32-CAM, чтобы запустить выполнение кода. Затем вы можете открыть Serial Monitor, чтобы видеть, что происходит в фоновом режиме.

Перейдите в свою учётную запись Telegram и откройте разговор с вашим ботом. Отправьте следующие команды и посмотрите, как бот отвечает:

/start показывает приветственное сообщение с допустимыми командами;
/flash переключает состояние вспышки;
/photo делает новое фото и отправляет его в вашу учётную запись Telegram.

ESP32-CAM съёмка и отправка фото в Telegram — демонстрация

Одновременно в Serial Monitor вы должны увидеть, что ESP32-CAM получает сообщения.

ESP32-CAM отправка фото в Telegram — Serial Monitor

Если вы попытаетесь взаимодействовать с ботом из другой учётной записи, вы получите сообщение «Unauthorized user».

Управление ESP32 ESP8266 выходами Telegram — неавторизованный пользователь

Заключение 

В этом руководстве вы узнали, как отправить фото с ESP32-CAM в вашу учётную запись Telegram. Если у вас есть доступ к интернету на смартфоне, вы можете запросить новое фото, где бы вы ни находились. Это отлично подходит для мониторинга вашей ESP32-CAM из любой точки мира.

У нас есть другие руководства по использованию Telegram, которые могут вас заинтересовать: