ESP32-CAM: Датчик движения PIR с захватом фото (сохранение на microSD)

В этом проекте мы создадим детектор движения с захватом фотографий, используя ESP32-CAM. Когда PIR-датчик обнаруживает движение, ESP32 просыпается, делает фото и сохраняет его на карте microSD.

ESP32-CAM детектор движения PIR с захватом фото (сохранение на microSD карту)

Этот проект очень похож на предыдущий, но после многочисленных просьб мы добавили PIR-датчик движения в схему. Таким образом, при обнаружении движения делается снимок и сохраняется на карте microSD.

Другие проекты и руководства по ESP32-CAM:

У нас есть аналогичный проект с использованием Raspberry Pi и модуля камеры:

Raspberry Pi: детектор движения с захватом фото

Смотрите видеоурок

Вы можете посмотреть видеоурок или продолжить чтение для получения полных инструкций по проекту.

Необходимые компоненты

Для этого проекта вам понадобятся следующие компоненты:

ESP32-CAM с OV2640 – рекомендации
Карта MicroSD
PIR-датчик движения
FTDI-программатор
Перемычки (мама-мама)
Блок питания 5V для ESP32-CAM или Power Bank (опционально)

Обзор проекта

Вот краткий обзор того, как работает проект:

ESP32-CAM находится в режиме глубокого сна (deep sleep) с внешним пробуждением.
При обнаружении движения PIR-датчик отправляет сигнал для пробуждения ESP32.
ESP32-CAM делает фото и сохраняет его на карте microSD.
Затем он возвращается в режим глубокого сна, пока не будет получен новый сигнал от PIR-датчика.

Рекомендуемое чтение: ESP32 Deep Sleep с Arduino IDE и источниками пробуждения

Предварительные требования

Перед началом работы убедитесь, что вы выполнили следующие предварительные требования.

Форматирование карты MicroSD

Первое, что мы рекомендуем сделать — отформатировать карту microSD. Вы можете использовать встроенный инструмент форматирования Windows или любое другое программное обеспечение для форматирования microSD.

1. Вставьте карту microSD в компьютер. Перейдите в Мой компьютер и щёлкните правой кнопкой мыши на SD-карту. Выберите Форматировать, как показано на рисунке ниже.

2. Появится новое окно. Выберите FAT32, нажмите Начать для запуска процесса форматирования и следуйте инструкциям на экране.

Примечание

Согласно спецификациям продукта, ESP32-CAM должна поддерживать только SD-карты ёмкостью 4 ГБ. Однако мы тестировали с SD-картой на 16 ГБ, и она работает отлично.

Установка плат ESP32 в Arduino IDE

Мы будем программировать плату ESP32 с помощью Arduino IDE. Поэтому вам нужна установленная Arduino IDE, а также платы ESP32. Следуйте этому руководству, если вы ещё этого не сделали:

Установка платы ESP32 в Arduino IDE (Windows, Mac OS X, Linux)

Deep Sleep с внешним пробуждением

В этом проекте ESP32-CAM будет находиться в режиме глубокого сна, и он проснётся от внешнего источника пробуждения (PIR-датчик движения отправляет HIGH-сигнал при обнаружении движения).

Только RTC GPIO можно использовать в качестве источника пробуждения. RTC GPIO ESP32: 0, 2, 4, 12, 13, 14, 15, 25, 26, 27, 32, 33, 34, 35, 36 и 39.

Давайте вспомним распиновку ESP32-CAM.

GPIO 4, GPIO 2, GPIO 14, GPIO 15, GPIO 13 и GPIO 12 — все используются картой microSD. Но если мы используем microSD в 1-битном режиме, мы можем освободить GPIO 12 и GPIO 13. Именно так мы и поступим: будем использовать microSD в 1-битном режиме, а GPIO 13 — для подключения PIR-датчика движения.

ESP32-CAM: Съёмка фото с PIR-датчиком движения — Код

Скопируйте следующий код в вашу Arduino IDE.

/*********
  Rui Santos & Sara Santos - Random Nerd Tutorials
  Подробности проекта: https://RandomNerdTutorials.com/esp32-cam-pir-motion-detector-photo-capture/

  ВАЖНО!!!
   - Выберите плату "AI Thinker ESP32-CAM"
   - GPIO 0 должен быть подключён к GND для загрузки скетча
   - После подключения GPIO 0 к GND нажмите кнопку RESET на плате ESP32-CAM для перевода в режим прошивки

  Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files.
  The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.
*********/

#include "esp_camera.h"
#include "Arduino.h"
#include "FS.h"                // SD Card ESP32
#include "SD_MMC.h"            // SD Card ESP32
#include "soc/soc.h"           // Disable brownout problems
#include "soc/rtc_cntl_reg.h"  // Disable brownout problems
#include "driver/rtc_io.h"
#include <EEPROM.h>            // read and write from flash memory
// define the number of bytes you want to access
#define EEPROM_SIZE 1

RTC_DATA_ATTR int bootCount = 0;

// Pin definition for CAMERA_MODEL_AI_THINKER
#define PWDN_GPIO_NUM     32
#define RESET_GPIO_NUM    -1
#define XCLK_GPIO_NUM      0
#define SIOD_GPIO_NUM     26
#define SIOC_GPIO_NUM     27
#define Y9_GPIO_NUM       35
#define Y8_GPIO_NUM       34
#define Y7_GPIO_NUM       39
#define Y6_GPIO_NUM       36
#define Y5_GPIO_NUM       21
#define Y4_GPIO_NUM       19
#define Y3_GPIO_NUM       18
#define Y2_GPIO_NUM        5
#define VSYNC_GPIO_NUM    25
#define HREF_GPIO_NUM     23
#define PCLK_GPIO_NUM     22

int pictureNumber = 0;

void setup() {
  WRITE_PERI_REG(RTC_CNTL_BROWN_OUT_REG, 0); //disable brownout detector
  Serial.begin(115200);

  Serial.setDebugOutput(true);

  camera_config_t config;
  config.ledc_channel = LEDC_CHANNEL_0;
  config.ledc_timer = LEDC_TIMER_0;
  config.pin_d0 = Y2_GPIO_NUM;
  config.pin_d1 = Y3_GPIO_NUM;
  config.pin_d2 = Y4_GPIO_NUM;
  config.pin_d3 = Y5_GPIO_NUM;
  config.pin_d4 = Y6_GPIO_NUM;
  config.pin_d5 = Y7_GPIO_NUM;
  config.pin_d6 = Y8_GPIO_NUM;
  config.pin_d7 = Y9_GPIO_NUM;
  config.pin_xclk = XCLK_GPIO_NUM;
  config.pin_pclk = PCLK_GPIO_NUM;
  config.pin_vsync = VSYNC_GPIO_NUM;
  config.pin_href = HREF_GPIO_NUM;
  config.pin_sccb_sda = SIOD_GPIO_NUM;
  config.pin_sccb_scl = SIOC_GPIO_NUM;
  config.pin_pwdn = PWDN_GPIO_NUM;
  config.pin_reset = RESET_GPIO_NUM;
  config.xclk_freq_hz = 20000000;
  config.pixel_format = PIXFORMAT_JPEG;
  config.grab_mode = CAMERA_GRAB_LATEST;

  pinMode(4, INPUT);
  digitalWrite(4, LOW);
  rtc_gpio_hold_dis(GPIO_NUM_4);

  if(psramFound()){
    config.frame_size = FRAMESIZE_UXGA; // FRAMESIZE_ + QVGA|CIF|VGA|SVGA|XGA|SXGA|UXGA
    config.jpeg_quality = 10;
    config.fb_count = 2;
  } else {
    config.frame_size = FRAMESIZE_SVGA;
    config.jpeg_quality = 12;
    config.fb_count = 1;
  }

  // Init Camera
  esp_err_t err = esp_camera_init(&config);
  if (err != ESP_OK) {
    Serial.printf("Camera init failed with error 0x%x", err);
    return;
  }

  Serial.println("Starting SD Card");

  delay(500);
  if (!SD_MMC.begin("/sdcard", true)) { // true enables 1-bit mode to free up GPIOs
    Serial.println("SD Card Mount Failed");
    //return;
  }

  uint8_t cardType = SD_MMC.cardType();
  if(cardType == CARD_NONE){
    Serial.println("No SD Card attached");
    return;
  }

  camera_fb_t * fb = NULL;

  // Take Picture with Camera
  fb = esp_camera_fb_get();
  if(!fb) {
    Serial.println("Camera capture failed");
    return;
  }
  // initialize EEPROM with predefined size
  EEPROM.begin(EEPROM_SIZE);
  pictureNumber = EEPROM.read(0) + 1;

  // Path where new picture will be saved in SD Card
  String path = "/picture" + String(pictureNumber) +".jpg";

  fs::FS &fs = SD_MMC;
  Serial.printf("Picture file name: %s\n", path.c_str());

  File file = fs.open(path.c_str(), FILE_WRITE);
  if(!file){
    Serial.println("Failed to open file in writing mode");
  }
  else {
    file.write(fb->buf, fb->len); // payload (image), payload length
    Serial.printf("Saved file to path: %s\n", path.c_str());
    EEPROM.write(0, pictureNumber);
    EEPROM.commit();
  }
  file.close();
  esp_camera_fb_return(fb);

  delay(1000);

  // Turns off the ESP32-CAM white on-board LED (flash) connected to GPIO 4
  pinMode(4, OUTPUT);
  digitalWrite(4, LOW);
  rtc_gpio_hold_en(GPIO_NUM_4);

  esp_sleep_enable_ext0_wakeup(GPIO_NUM_13, 1);
  rtc_gpio_pullup_dis(GPIO_NUM_13);
  rtc_gpio_pulldown_en(GPIO_NUM_13);

  Serial.println("Going to sleep now");
  delay(1000);
  esp_deep_sleep_start();
  Serial.println("This will never be printed");
}

void loop() {

}

Просмотреть исходный код

Этот код аналогичен одному из наших предыдущих проектов ESP32-CAM, но он включает внешнее пробуждение на GPIO 13. Мы также отключаем внутренние подтягивающие резисторы (pull-up) и включаем внутренние резисторы (pull-down), чтобы исключить ложные срабатывания.

esp_sleep_enable_ext0_wakeup(GPIO_NUM_13, 1);
rtc_gpio_pullup_dis(GPIO_NUM_13);
rtc_gpio_pulldown_en(GPIO_NUM_13);

Если вы хотите узнать больше о внешнем пробуждении ESP32, рекомендуем прочитать это руководство:

ESP32: внешнее пробуждение из глубокого сна

Кроме того, мы инициализируем карту microSD в 1-битном режиме в следующих строках:

if (!SD_MMC.begin("/sdcard", true)) { // true enables 1-bit mode to free up GPIOs
  Serial.println("SD Card Mount Failed");
  //return;
}

Чтобы узнать больше о коде, перейдите к следующему проекту:

ESP32-CAM: съёмка фото и сохранение на MicroSD

Загрузка кода в ESP32-CAM

Для загрузки кода на плату ESP32-CAM подключите её к компьютеру с помощью FTDI-программатора или ESP32-CAM MB программатора.

Если вы используете FTDI-программатор, следуйте следующей схеме подключения:

ESP32-CAM подключение к FTDI-программатору для загрузки программы через Arduino IDE

Многие FTDI-программаторы имеют перемычку, которая позволяет выбрать 3.3V или 5V. Убедитесь, что перемычка установлена в правильное положение для выбора 5V.

Важно: GPIO 0 должен быть подключён к GND, чтобы вы могли загрузить скетч.

ESP32-CAM	FTDI-программатор
GND	GND
5V	VCC (5V)
U0R	TX
U0T	RX
GPIO 0	GND

Для загрузки кода выполните следующие шаги:

Перейдите в Tools > Board и выберите AI-Thinker ESP32-CAM.
Перейдите в Tools > Port и выберите COM-порт, к которому подключён ESP32.
Затем нажмите кнопку загрузки для загрузки кода.

Когда в окне отладки начнут появляться точки, как показано ниже, нажмите встроенную кнопку RST на ESP32-CAM.

После нескольких секунд код должен быть успешно загружен на вашу плату. После этого можно отключить GPIO 0 от GND и открыть монитор порта (Serial Monitor).

Схема подключения

Подключите вывод данных PIR-датчика движения к GPIO 13, как показано на следующей схеме.

Во избежание проблем при загрузке рекомендуем собирать схему только после загрузки кода.

Демонстрация

После загрузки кода и сборки схемы вставьте отформатированную карту microSD для тестирования.

Затем нажмите кнопку сброса (RST), и устройство должно начать работать. При обнаружении движения оно включает вспышку, делает фото и сохраняет его на карте microSD. Затем оно переходит в режим глубокого сна и снова просыпается при обнаружении движения.

ESP32-CAM с PIR-датчиком движения - монитор порта, тестирование сохранения фото на microSD

Поэкспериментируйте с этой схемой несколько раз, чтобы убедиться, что она работает. Затем вставьте карту microSD в компьютер, чтобы просмотреть сделанные фотографии.

ESP32-CAM сделанные фотографии на карте microSD

Вот пример:

Теперь вы можете завершить этот проект по своему усмотрению. Вы можете использовать муляж камеры наблюдения и вставить в него ESP32-CAM с PIR-датчиком движения, или вы можете сделать свой собственный корпус. Ниже мы покажем два различных варианта.

ESP32-CAM с PIR-датчиком движения в муляже камеры наблюдения

Устранение неполадок

Если вы получаете какую-либо из следующих ошибок, прочитайте наше Руководство по устранению неполадок ESP32-CAM: исправление самых распространённых проблем:

Failed to connect to ESP32: Timed out waiting for packet header
Camera init failed with error 0x20001 или аналогичная
Brownout detector или Guru meditation error
Sketch too big error – выбрана неправильная схема разделов
Board at COMX is not available – COM-порт не выбран
Psram error: GPIO isr service is not installed
Слабый сигнал Wi-Fi
Нет IP-адреса в мониторе порта Arduino IDE
Не удаётся открыть веб-сервер
Изображение тормозит/показывает большую задержку

Заключение

Надеемся, вам понравился этот проект. Для большего количества проектов с ESP32-CAM ознакомьтесь с нашей электронной книгой с 20 различными проектами: Build ESP32-CAM Projects (eBook)

Вы также можете ознакомиться со всеми нашими опубликованными проектами ESP32-CAM по следующей ссылке:

Все наши проекты ESP32-CAM

Спасибо за чтение.