ESP8266 NodeMCU MQTT – публикация показаний температуры и влажности DHT11/DHT22 (Arduino IDE)

Узнайте, как публиковать показания температуры и влажности с датчика DHT11 или DHT22 через MQTT с помощью ESP8266 NodeMCU на любую платформу, поддерживающую MQTT, или в любой MQTT-клиент. В качестве примера мы будем публиковать показания датчика в Node-RED Dashboard, а программирование ESP8266 будет выполняться с помощью Arduino IDE.

Рекомендуем прочитать: Что такое MQTT и как он работает

Обзор проекта

На следующей диаграмме показан общий обзор проекта, который мы будем создавать.

• ESP8266 запрашивает показания температуры и влажности с датчика DHT11 или DHT22;

• Показания температуры публикуются в топике esp/dht/temperature;

• Показания влажности публикуются в топике esp/dht/humidity;

• Node-RED подписан на эти топики;

• Node-RED получает показания датчика и отображает их на шкалах (gauges);

• Вы можете получать показания на любой другой платформе, поддерживающей MQTT, и обрабатывать их по своему усмотрению.

Предварительные требования

Прежде чем приступить к этому руководству, убедитесь, что вы выполнили следующие предварительные требования.

Arduino IDE

Мы будем программировать ESP8266 с помощью Arduino IDE, поэтому убедитесь, что у вас установлено дополнение ESP8266.

• Установка платы ESP8266 в Arduino IDE (Windows, Mac OS X, Linux)

MQTT-брокер

Для использования MQTT вам нужен брокер. Мы будем использовать брокер Mosquitto, установленный на Raspberry Pi. Прочитайте Как установить брокер Mosquitto на Raspberry Pi.

Вы можете использовать любой другой MQTT-брокер, включая облачный MQTT-брокер. Мы покажем вам, как это сделать в коде далее.

Если вы не знакомы с MQTT, обязательно прочитайте наше вводное руководство: Что такое MQTT и как он работает.

Библиотеки MQTT

Для использования MQTT с ESP8266 мы будем использовать библиотеку Async MQTT Client.

Установка библиотеки Async MQTT Client

1. Нажмите здесь, чтобы скачать библиотеку Async MQTT client. У вас должен появиться .zip-файл в папке загрузок.

2. Распакуйте .zip-файл, и вы получите папку async-mqtt-client-master.

3. Переименуйте папку из async-mqtt-client-master в async_mqtt_client.

4. Переместите папку async_mqtt_client в папку библиотек вашей установки Arduino IDE.

5. Наконец, перезапустите Arduino IDE.

Альтернативно, вы можете перейти в Sketch > Include Library > Add .ZIP library и выбрать библиотеку, которую вы только что скачали.

Установка библиотеки ESPAsync TCP

Для использования MQTT с ESP8266 вам также нужна библиотека ESPAsync TCP.

1. Нажмите здесь, чтобы скачать библиотеку ESPAsync TCP. У вас должен появиться .zip-файл в папке загрузок.

2. Распакуйте .zip-файл, и вы получите папку ESPAsyncTCP-master.

3. Переименуйте папку из ESPAsyncTCP-master в ESPAsyncTCP.

4. Переместите папку ESPAsyncTCP в папку библиотек вашей установки Arduino IDE.

5. Наконец, перезапустите Arduino IDE.

Альтернативно, вы можете перейти в Sketch > Include Library > Add .ZIP library и выбрать библиотеку, которую вы только что скачали.

Библиотеки датчика DHT

Для чтения данных с датчика DHT мы будем использовать библиотеку DHT от Adafruit. Для использования этой библиотеки вам также необходимо установить библиотеку Adafruit Unified Sensor. Выполните следующие шаги для установки этих библиотек.

1. Откройте Arduino IDE и перейдите в Sketch > Include Library > Manage Libraries. Должен открыться менеджер библиотек.

2. Введите «DHT» в поле поиска и установите библиотеку DHT от Adafruit.

3. После установки библиотеки DHT от Adafruit введите «Adafruit Unified Sensor» в поле поиска. Прокрутите до конца, найдите библиотеку и установите её.

После установки библиотек перезапустите Arduino IDE.

Необходимые компоненты

Для этого руководства вам понадобятся следующие компоненты:

• ESP8266 (читайте Сравнение лучших плат ESP8266 для разработки)

• DHT11 или DHT22 – Руководство по DHT с ESP8266

• Резистор 4,7 кОм

• Плата Raspberry Pi (читайте Лучшие стартовые наборы Raspberry Pi)

• Карта MicroSD – 16 ГБ Class10

• Блок питания Raspberry Pi (5V 2.5A)

• Соединительные провода

• Макетная плата

Вы можете использовать ссылки выше или перейти непосредственно на MakerAdvisor.com/tools, чтобы найти все компоненты для ваших проектов по лучшей цене!

Схема подключения

Подключите DHT11 или DHT22 к ESP8266, как показано на следующей схеме, с выводом данных, подключённым к GPIO 14.

Примечание: если у вас датчик DHT на плате расширения, он имеет только три вывода и встроенный подтягивающий резистор на выводе 2, поэтому вам не нужно подключать внешний резистор. Вам нужно подключить только VCC, данные и GND.

В этом примере мы подключаем вывод данных DHT к GPIO 14. Однако вы можете использовать любой другой подходящий цифровой вывод.

Узнайте, как использовать GPIO ESP8266, из нашего руководства: Справочник по распиновке ESP8266: Какие выводы GPIO следует использовать?

Код

Скопируйте следующий код в вашу Arduino IDE. Чтобы он работал для вас, вам нужно вставить свои сетевые учётные данные, а также данные MQTT-брокера.

/*
  Rui Santos
  Complete project details at https://RandomNerdTutorials.com/esp8266-nodemcu-mqtt-publish-dht11-dht22-arduino/

  Permission is hereby granted, free of charge, to any person obtaining a copy
  of this software and associated documentation files.

  The above copyright notice and this permission notice shall be included in all
  copies or substantial portions of the Software.
*/

#include "DHT.h"
#include <ESP8266WiFi.h>
#include <Ticker.h>
#include <AsyncMqttClient.h>

#define WIFI_SSID "REPLACE_WITH_YOUR_SSID"
#define WIFI_PASSWORD "REPLACE_WITH_YOUR_PASSWORD"

// Raspberri Pi Mosquitto MQTT Broker
#define MQTT_HOST IPAddress(192, 168, 1, XXX)
// For a cloud MQTT broker, type the domain name
//#define MQTT_HOST "example.com"
#define MQTT_PORT 1883

// Temperature MQTT Topics
#define MQTT_PUB_TEMP "esp/dht/temperature"
#define MQTT_PUB_HUM "esp/dht/humidity"

// Digital pin connected to the DHT sensor
#define DHTPIN 14

// Uncomment whatever DHT sensor type you're using
//#define DHTTYPE DHT11   // DHT 11
#define DHTTYPE DHT22   // DHT 22  (AM2302), AM2321
//#define DHTTYPE DHT21   // DHT 21 (AM2301)

// Initialize DHT sensor
DHT dht(DHTPIN, DHTTYPE);

// Variables to hold sensor readings
float temp;
float hum;

AsyncMqttClient mqttClient;
Ticker mqttReconnectTimer;

WiFiEventHandler wifiConnectHandler;
WiFiEventHandler wifiDisconnectHandler;
Ticker wifiReconnectTimer;

unsigned long previousMillis = 0;   // Stores last time temperature was published
const long interval = 10000;        // Interval at which to publish sensor readings

void connectToWifi() {
  Serial.println("Connecting to Wi-Fi...");
  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
}

void onWifiConnect(const WiFiEventStationModeGotIP& event) {
  Serial.println("Connected to Wi-Fi.");
  connectToMqtt();
}

void onWifiDisconnect(const WiFiEventStationModeDisconnected& event) {
  Serial.println("Disconnected from Wi-Fi.");
  mqttReconnectTimer.detach(); // ensure we don't reconnect to MQTT while reconnecting to Wi-Fi
  wifiReconnectTimer.once(2, connectToWifi);
}

void connectToMqtt() {
  Serial.println("Connecting to MQTT...");
  mqttClient.connect();
}

void onMqttConnect(bool sessionPresent) {
  Serial.println("Connected to MQTT.");
  Serial.print("Session present: ");
  Serial.println(sessionPresent);
}

void onMqttDisconnect(AsyncMqttClientDisconnectReason reason) {
  Serial.println("Disconnected from MQTT.");

  if (WiFi.isConnected()) {
    mqttReconnectTimer.once(2, connectToMqtt);
  }
}

/*void onMqttSubscribe(uint16_t packetId, uint8_t qos) {
  Serial.println("Subscribe acknowledged.");
  Serial.print("  packetId: ");
  Serial.println(packetId);
  Serial.print("  qos: ");
  Serial.println(qos);
}

void onMqttUnsubscribe(uint16_t packetId) {
  Serial.println("Unsubscribe acknowledged.");
  Serial.print("  packetId: ");
  Serial.println(packetId);
}*/

void onMqttPublish(uint16_t packetId) {
  Serial.print("Publish acknowledged.");
  Serial.print("  packetId: ");
  Serial.println(packetId);
}

void setup() {
  Serial.begin(115200);
  Serial.println();

  dht.begin();

  wifiConnectHandler = WiFi.onStationModeGotIP(onWifiConnect);
  wifiDisconnectHandler = WiFi.onStationModeDisconnected(onWifiDisconnect);

  mqttClient.onConnect(onMqttConnect);
  mqttClient.onDisconnect(onMqttDisconnect);
  //mqttClient.onSubscribe(onMqttSubscribe);
  //mqttClient.onUnsubscribe(onMqttUnsubscribe);
  mqttClient.onPublish(onMqttPublish);
  mqttClient.setServer(MQTT_HOST, MQTT_PORT);
  // If your broker requires authentication (username and password), set them below
  //mqttClient.setCredentials("REPlACE_WITH_YOUR_USER", "REPLACE_WITH_YOUR_PASSWORD");

  connectToWifi();
}

void loop() {
  unsigned long currentMillis = millis();
  // Every X number of seconds (interval = 10 seconds)
  // it publishes a new MQTT message
  if (currentMillis - previousMillis >= interval) {
    // Save the last time a new reading was published
    previousMillis = currentMillis;
    // New DHT sensor readings
    hum = dht.readHumidity();
    // Read temperature as Celsius (the default)
    temp = dht.readTemperature();
    // Read temperature as Fahrenheit (isFahrenheit = true)
    //temp = dht.readTemperature(true);

    // Publish an MQTT message on topic esp/dht/temperature
    uint16_t packetIdPub1 = mqttClient.publish(MQTT_PUB_TEMP, 1, true, String(temp).c_str());
    Serial.printf("Publishing on topic %s at QoS 1, packetId: %i ", MQTT_PUB_TEMP, packetIdPub1);
    Serial.printf("Message: %.2f \n", temp);

    // Publish an MQTT message on topic esp/dht/humidity
    uint16_t packetIdPub2 = mqttClient.publish(MQTT_PUB_HUM, 1, true, String(hum).c_str());
    Serial.printf("Publishing on topic %s at QoS 1, packetId %i: ", MQTT_PUB_HUM, packetIdPub2);
    Serial.printf("Message: %.2f \n", hum);
  }
}

Посмотреть исходный код

Как работает код

Следующий раздел импортирует все необходимые библиотеки.

#include "DHT.h"
#include <ESP8266WiFi.h>
#include <Ticker.h>
#include <AsyncMqttClient.h>

Введите свои сетевые учётные данные в следующих строках.

#define WIFI_SSID "REPLACE_WITH_YOUR_SSID"
#define WIFI_PASSWORD "REPLACE_WITH_YOUR_PASSWORD"

Вставьте IP-адрес Raspberry Pi, чтобы ESP8266 подключился к вашему брокеру.

#define MQTT_HOST IPAddress(192, 168, 1, 106)

Если вы используете облачный MQTT-брокер, вставьте доменное имя брокера, например:

#define MQTT_HOST "example.com"

Определите порт MQTT.

#define MQTT_PORT 1883

Температура и влажность будут публиковаться в следующих топиках:

#define MQTT_PUB_TEMP "esp/dht/temperature"
#define MQTT_PUB_HUM "esp/dht/humidity"

Определите GPIO, к которому подключён вывод данных датчика DHT. В нашем случае он подключён к GPIO 14.

#define DHTPIN 14

Раскомментируйте тип используемого датчика DHT. В нашем примере мы используем DHT22.

//#define DHTTYPE DHT11   // DHT 11
#define DHTTYPE DHT22     // DHT 22 (AM2302), AM2321
//#define DHTTYPE DHT21   // DHT 21 (AM2301)

Инициализируйте датчик DHT на выводе и типе, определённых ранее.

DHT dht(DHTPIN, DHTTYPE);

Переменные temp и hum будут хранить значения температуры и влажности с датчика DHT22.

float temp;
float hum;

Создайте объект AsyncMqttClient с именем mqttClient для управления MQTT-клиентом и таймеры для переподключения к MQTT-брокеру и маршрутизатору при потере соединения.

AsyncMqttClient mqttClient;
Ticker mqttReconnectTimer;

WiFiEventHandler wifiConnectHandler;
WiFiEventHandler wifiDisconnectHandler;
Ticker wifiReconnectTimer;

Затем создайте вспомогательные переменные таймера для публикации показаний каждые 10 секунд. Вы можете изменить время задержки в переменной interval.

unsigned long previousMillis = 0;  // Stores last time temperature was published
const long interval = 10000;       // Interval at which to publish sensor readings

Примечание: датчики DHT11 и DHT22 имеют низкую частоту дискретизации. Вы можете запрашивать показания DHT11 только каждую секунду, а DHT22 – каждые две секунды.

Функции MQTT: подключение к Wi-Fi, подключение к MQTT и события Wi-Fi

Мы не добавляли комментарии к функциям, определённым в следующем разделе кода. Эти функции поставляются с библиотекой Async Mqtt Client. Названия функций достаточно информативны.

Например, функция connectToWifi() подключает ваш ESP8266 к маршрутизатору:

void connectToWifi() {
  Serial.println("Connecting to Wi-Fi...");
  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
}

Функция connectToMqtt() подключает ваш ESP8266 к MQTT-брокеру:

void connectToMqtt() {
  Serial.println("Connecting to MQTT...");
  mqttClient.connect();
}

Функция onMqttConnect() выполняется после начала сессии с брокером.

void onMqttConnect(bool sessionPresent) {
  Serial.println("Connected to MQTT.");
  Serial.print("Session present: ");
  Serial.println(sessionPresent);
}

Функции MQTT: отключение и публикация

Если ESP8266 теряет соединение с MQTT-брокером, вызывается функция onMqttDisconnect, которая выводит сообщение в Serial Monitor.

void onMqttDisconnect(AsyncMqttClientDisconnectReason reason) {
  Serial.println("Disconnected from MQTT.");

  if (WiFi.isConnected()) {
    mqttReconnectTimer.once(2, connectToMqtt);
  }
}

Когда вы публикуете сообщение в MQTT-топик, вызывается функция onMqttPublish(). Она выводит идентификатор пакета в Serial Monitor.

void onMqttPublish(uint16_t packetId) {
  Serial.print("Publish acknowledged.");
  Serial.print("  packetId: ");
  Serial.println(packetId);
}

По сути, все эти функции, которые мы только что упомянули, являются функциями обратного вызова (callback). Поэтому они выполняются асинхронно.

setup()

Теперь перейдём к функции setup(). Инициализируйте датчик DHT.

dht.begin();

Следующие две строки создают обработчики, которые позволят MQTT-брокеру и Wi-Fi соединению переподключиться в случае потери связи.

wifiConnectHandler = WiFi.onStationModeGotIP(onWifiConnect);
wifiDisconnectHandler = WiFi.onStationModeDisconnected(onWifiDisconnect);

Наконец, назначьте все функции обратного вызова. Это означает, что эти функции будут выполняться автоматически при необходимости. Например, когда ESP8266 подключается к брокеру, автоматически вызывается функция onMqttConnect(), и так далее.

mqttClient.onConnect(onMqttConnect);
mqttClient.onDisconnect(onMqttDisconnect);
//mqttClient.onSubscribe(onMqttSubscribe);
//mqttClient.onUnsubscribe(onMqttUnsubscribe);
mqttClient.onPublish(onMqttPublish);
mqttClient.setServer(MQTT_HOST, MQTT_PORT);

Аутентификация брокера

Если ваш брокер требует аутентификации, раскомментируйте следующую строку и вставьте свои учётные данные (имя пользователя и пароль).

mqttClient.setCredentials("REPlACE_WITH_YOUR_USER", "REPLACE_WITH_YOUR_PASSWORD");

Наконец, подключитесь к Wi-Fi.

connectToWifi();

loop()

В функции loop() вы создаёте таймер, который позволяет получать новые показания температуры и влажности с датчика DHT и публиковать их в соответствующий топик каждые 10 секунд.

unsigned long currentMillis = millis();
// Every X number of seconds (interval = 10 seconds)
// it publishes a new MQTT message
if (currentMillis - previousMillis >= interval) {
  // Save the last time a new reading was published
  previousMillis = currentMillis;
  // New DHT sensor readings
  hum = dht.readHumidity();
  // Read temperature as Celsius (the default)
  temp = dht.readTemperature();
  // Read temperature as Fahrenheit (isFahrenheit = true)
  //temp = dht.readTemperature(true);

Публикация в топики

Для публикации показаний в соответствующие MQTT-топики используйте следующие строки:

uint16_t packetIdPub1 = mqttClient.publish(MQTT_PUB_TEMP, 1, true, String(temp).c_str());
uint16_t packetIdPub2 = mqttClient.publish(MQTT_PUB_HUM, 1, true, String(hum).c_str());

По сути, используйте метод publish() объекта mqttClient для публикации данных в топик. Метод publish() принимает следующие аргументы по порядку:

• MQTT-топик (const char*)

• QoS (uint8_t): качество обслуживания – может быть 0, 1 или 2

• retain-флаг (bool): флаг сохранения

• payload (const char*) – в данном случае полезная нагрузка соответствует показанию датчика

QoS (quality of service, качество обслуживания) – это способ гарантировать доставку сообщения. Он может быть одного из следующих уровней:

• 0: сообщение будет доставлено один раз или не доставлено вообще. Сообщение не подтверждается. Нет возможности дублирования сообщений;

• 1: сообщение будет доставлено как минимум один раз, но может быть доставлено более одного раза;

• 2: сообщение всегда доставляется ровно один раз;

• Узнайте больше о MQTT QoS.

Загрузка кода

С включённым Raspberry Pi и запущенным MQTT-брокером Mosquitto загрузите код в ESP8266.

Откройте Serial Monitor с частотой 115200 бод, и вы увидите, что ESP8266 начинает публиковать сообщения в топики, которые мы определили ранее.

Подготовка Node-RED Dashboard

ESP8266 публикует показания температуры каждые 10 секунд в топиках esp/dht/temperature и esp/dht/humidity. Теперь вы можете использовать любую панель управления, поддерживающую MQTT, или любое другое устройство, поддерживающее MQTT, для подписки на эти топики и получения показаний.

В качестве примера мы создадим простой поток (flow) с помощью Node-RED для подписки на эти топики и отображения показаний на шкалах (gauges).

Если у вас не установлен Node-RED, следуйте следующим руководствам:

• Начало работы с Node-RED на Raspberry Pi

• Установка и начало работы с Node-RED Dashboard

Когда Node-RED запущен на вашем Raspberry Pi, перейдите по IP-адресу вашего Raspberry Pi с добавлением :1880.

http://raspberry-pi-ip-address:1880

Должен открыться интерфейс Node-RED. Перетащите два узла MQTT in и два узла gauge в поток.

Нажмите на узел MQTT и отредактируйте его свойства.

Поле Server относится к MQTT-брокеру. В нашем случае MQTT-брокер – это Raspberry Pi, поэтому установлено значение localhost:1883. Если вы используете облачный MQTT-брокер, вам следует изменить это поле.

Вставьте топик, на который хотите подписаться, и QoS. Предыдущий узел MQTT подписан на топик esp/dht/temperature.

Нажмите на другой узел MQTT in и отредактируйте его свойства с тем же сервером, но для другого топика: esp/dht/humidity.

Нажмите на узлы gauge и отредактируйте их свойства для каждого показания. Следующий узел настроен для показаний температуры. Отредактируйте другой узел gauge для показаний влажности.

Соедините узлы, как показано ниже:

Наконец, разверните поток (нажмите кнопку в правом верхнем углу).

Альтернативно, вы можете перейти в Menu > Import и скопировать следующее в ваш Clipboard, чтобы создать поток Node-RED.

[{"id":"59f95d85.b6f0b4","type":"mqtt in","z":"b01416d3.f69f38","name":"","topic":"esp/dht/temperature","qos":"1","datatype":"auto","broker":"8db3fac0.99dd48","x":910,"y":340,"wires":[["2babfd19.559212"]]},{"id":"2babfd19.559212","type":"ui_gauge","z":"b01416d3.f69f38","name":"","group":"37de8fe8.46846","order":2,"width":0,"height":0,"gtype":"gage","title":"Temperature","label":"ºC","format":"{{value}}","min":0,"max":"40","colors":["#00b500","#f7df09","#ca3838"],"seg1":"","seg2":"","x":1210,"y":340,"wires":[]},{"id":"b9aa2398.37ca3","type":"mqtt in","z":"b01416d3.f69f38","name":"","topic":"esp/dht/humidity","qos":"1","datatype":"auto","broker":"8db3fac0.99dd48","x":900,"y":420,"wires":[["d0f75e86.1c9ae"]]},{"id":"d0f75e86.1c9ae","type":"ui_gauge","z":"b01416d3.f69f38","name":"","group":"37de8fe8.46846","order":2,"width":0,"height":0,"gtype":"gage","title":"Humidity","label":"%","format":"{{value}}","min":"30","max":"100","colors":["#53a4e6","#1d78a9","#4e38c9"],"seg1":"","seg2":"","x":1200,"y":420,"wires":[]},{"id":"8db3fac0.99dd48","type":"mqtt-broker","z":"","name":"","broker":"localhost","port":"1883","clientid":"","usetls":false,"compatmode":false,"keepalive":"60","cleansession":true,"birthTopic":"","birthQos":"0","birthPayload":"","closeTopic":"","closeQos":"0","closePayload":"","willTopic":"","willQos":"0","willPayload":""},{"id":"37de8fe8.46846","type":"ui_group","z":"","name":"BME280","tab":"53b8c8f9.cfbe48","order":1,"disp":true,"width":"6","collapse":false},{"id":"53b8c8f9.cfbe48","type":"ui_tab","z":"","name":"Home","icon":"dashboard","order":2,"disabled":false,"hidden":false}]

Посмотреть исходный код

Демонстрация

Перейдите по IP-адресу вашего Raspberry Pi с добавлением :1880/ui.

http://raspberry-pi-ip-address:1880/ui

Вы должны получить доступ к текущим показаниям температуры и влажности DHT на панели Dashboard. Вы можете использовать другие типы узлов dashboard для отображения показаний различными способами.

Вот и всё! Ваша плата ESP8266 публикует показания температуры и влажности DHT в Node-RED через MQTT.

Заключение

MQTT – отличный протокол связи для обмена небольшими объёмами данных между устройствами. В этом руководстве вы узнали, как публиковать показания температуры и влажности с датчика DHT с помощью ESP8266 в различные MQTT-топики. Затем вы можете использовать любое устройство или платформу домашней автоматизации для подписки на эти топики и получения показаний.

Вместо DHT вы можете использовать другой датчик:

• ESP8266 MQTT – Публикация показаний температуры DS18B20

• ESP8266 MQTT – Публикация показаний температуры, влажности и давления BME280

Мы надеемся, что это руководство было для вас полезным. Если вы хотите узнать больше об ESP8266, ознакомьтесь с нашими ресурсами:

• Домашняя автоматизация с использованием ESP8266

• Программирование на MicroPython с ESP32 и ESP8266

• Другие проекты ESP8266 NodeMCU…

Спасибо за чтение.