Руководство по работе с SD-картами на Arduino

Серия примеров чтения и записи данных на SD-карту с Arduino.

Автор: Arduino

Последнее обновление: 30.09.2025

Примечание

Эта статья была пересмотрена 18.11.2021 Карлом Сёдерби (Karl Söderby).

В этом руководстве собраны совместимые аппаратные средства и примеры кода, которые помогут вам начать работу с картами Secure Digital (SD).

Примеры в данном руководстве взяты из библиотеки SD, которая изначально основана на SdFat Уильяма Грейман (William Greiman).

Необходимое оборудование и программное обеспечение 

Плата Arduino со слотом для SD-карты*
Arduino IDE (онлайн или офлайн).
Отформатированная SD-карта

*Список плат/шилдов со слотом для SD-карты приведён ниже:

Схема подключения 

Ниже показан пример вставки SD-карты в плату MKR Zero. Ни один из приведённых ниже примеров не требует дополнительной схемы.

Обратите внимание: размер кластера определяется пользователем во время форматирования и имеет некоторые значения по умолчанию, которые можно изменить согласно определённым правилам. В приведённом выше скетче используется размер блока по умолчанию, равный 512 байтам согласно стандартам. Это значение не является размером кластера — он вычисляется как количество блоков на кластер. Более подробную информацию о размерах кластеров можно найти в этой статье.

Вывод файла 

Этот пример показывает, как прочитать файл с SD-карты с помощью библиотеки SD и передать его через последовательный порт.

На SD-карте находится файл с именем «datalog.txt». В loop() файл открывается при вызове SD.open(). Чтобы передать файл по последовательному порту на компьютер, используйте Serial.print(), считывая содержимое файла с помощью SD.read().

/*

  SD card file dump

  This example shows how to read a file from the SD card using the

  SD library and send it over the serial port.

  Pin numbers reflect the default SPI pins for Uno and Nano models.

  The circuit:

   SD card attached to SPI bus as follows:

 ** SDO - pin 11

 ** SDI - pin 12

 ** CLK - pin 13

 ** CS - depends on your SD card shield or module.

        Pin 10 used here for consistency with other Arduino examples

   (for MKRZero SD: SDCARD_SS_PIN)

  created  22 December 2010

  by Limor Fried

  modified 9 Apr 2012

  by Tom Igoe

  This example code is in the public domain.

*/
#include <SD.h>

const int chipSelect = 10;

void setup() {

  // Open serial communications and wait for port to open:

  Serial.begin(9600);

  // wait for Serial Monitor to connect. Needed for native USB port boards only:

  while (!Serial);

  Serial.print("Initializing SD card...");

  if (!SD.begin(chipSelect)) {

    Serial.println("initialization failed. Things to check:");

    Serial.println("1. is a card inserted?");

    Serial.println("2. is your wiring correct?");

    Serial.println("3. did you change the chipSelect pin to match your shield or module?");

    Serial.println("Note: press reset or reopen this serial monitor after fixing your issue!");

    while (true);

  }

  Serial.println("initialization done.");

  // open the file. note that only one file can be open at a time,

  // so you have to close this one before opening another.

  File dataFile = SD.open("datalog.txt");

  // if the file is available, write to it:

  if (dataFile) {

    while (dataFile.available()) {

      Serial.write(dataFile.read());

    }

    dataFile.close();

  }

  // if the file isn't open, pop up an error:

  else {

    Serial.println("error opening datalog.txt");

  }
}

void loop() {
}

Управление файлами 

Этот пример показывает, как создать и удалить файл на SD-карте.

В setup() откройте новый файл с помощью SD.open() с именем «example.txt». FILE_WRITE включает доступ к файлу на чтение и запись, начиная с конца. В этом примере, однако, сразу же закройте файл, вызвав myFile.close().

После проверки наличия файла с помощью SD.exists() удалите файл с карты с помощью SD.remove.

/*

  SD card basic file example

  This example shows how to create and destroy an SD card file

  The circuit. Pin numbers reflect the default

  SPI pins for Uno and Nano models:

   SD card attached to SPI bus as follows:

 ** SDO - pin 11

 ** SDI - pin 12

 ** CLK - pin 13

 ** CS - depends on your SD card shield or module.

        Pin 10 used here for consistency with other Arduino examples

    (for MKRZero SD: SDCARD_SS_PIN)

  created   Nov 2010

  by David A. Mellis

  modified 24 July 2020

  by Tom Igoe

  This example code is in the public domain.

*/
#include <SD.h>

const int chipSelect = 10;

File myFile;

void setup() {

  // Open serial communications and wait for port to open:

  Serial.begin(9600);

  // wait for Serial Monitor to connect. Needed for native USB port boards only:
  while (!Serial);

  Serial.print("Initializing SD card...");

  if (!SD.begin(10)) {

    Serial.println("initialization failed!");

    while (1);

  }

  Serial.println("initialization done.");

  if (SD.exists("example.txt")) {

    Serial.println("example.txt exists.");

  } else {

    Serial.println("example.txt doesn't exist.");

  }

  // open a new file and immediately close it:

  Serial.println("Creating example.txt...");

  myFile = SD.open("example.txt", FILE_WRITE);

  myFile.close();

  // Check to see if the file exists:

  if (SD.exists("example.txt")) {

    Serial.println("example.txt exists.");

  } else {

    Serial.println("example.txt doesn't exist.");

  }

  // delete the file:

  Serial.println("Removing example.txt...");

  SD.remove("example.txt");

  if (SD.exists("example.txt")) {

    Serial.println("example.txt exists.");

  } else {

    Serial.println("example.txt doesn't exist.");

  }
}

void loop() {

  // nothing happens after setup finishes.
}

Вывод списка файлов 

Этот пример показывает, как вывести список файлов, доступных в директории SD-карты.

Основной loop() ничего не делает, поскольку функция, выводящая файловый каталог «/» SD-карты, вызывается из setup(). Это сделано потому, что нам нужно увидеть его только один раз.

Функция printDirectory просматривает список записей и выводит в последовательный порт каждый файл и директорию. Для файлов также выводится их размер.

/*

  Listfiles

  This example shows how print out the files in a

  directory on a SD card. Pin numbers reflect the default

  SPI pins for Uno and Nano models

  The circuit:

   SD card attached to SPI bus as follows:

 ** SDO - pin 11

 ** SDI - pin 12

 ** CLK - pin 13

 ** CS - depends on your SD card shield or module.

        Pin 10 used here for consistency with other Arduino examples

    (for MKRZero SD: SDCARD_SS_PIN)

  created   Nov 2010

  by David A. Mellis

  modified 9 Apr 2012

  by Tom Igoe

  modified 2 Feb 2014

  by Scott Fitzgerald

  modified 24 July 2020

  by Tom Igoe

  This example code is in the public domain.

*/
#include <SD.h>

const int chipSelect = 10;

File root;

void setup() {

 // Open serial communications and wait for port to open:

  Serial.begin(9600);

  // wait for Serial Monitor to connect. Needed for native USB port boards only:

  while (!Serial);

  Serial.print("Initializing SD card...");

  if (!SD.begin(chipSelect)) {

    Serial.println("initialization failed. Things to check:");

    Serial.println("1. is a card inserted?");

    Serial.println("2. is your wiring correct?");

    Serial.println("3. did you change the chipSelect pin to match your shield or module?");

    Serial.println("Note: press reset or reopen this serial monitor after fixing your issue!");

    while (true);

  }

  Serial.println("initialization done.");

  root = SD.open("/");

  printDirectory(root, 0);

  Serial.println("done!");
}

void loop() {

  // nothing happens after setup finishes.
}

void printDirectory(File dir, int numTabs) {

  while (true) {

    File entry =  dir.openNextFile();

    if (! entry) {

      // no more files

      break;

    }

    for (uint8_t i = 0; i < numTabs; i++) {

      Serial.print('\t');

    }

    Serial.print(entry.name());

    if (entry.isDirectory()) {

      Serial.println("/");

      printDirectory(entry, numTabs + 1);

    } else {

      // files have sizes, directories do not

      Serial.print("\t\t");

      Serial.println(entry.size(), DEC);

    }

    entry.close();

  }
}

Руководство по работе с SD-картами на Arduino

Необходимое оборудование и программное обеспечение 

Схема подключения 

Примеры 

Чтение и запись 

Информация о карте 

Вывод файла 

Управление файлами 

Вывод списка файлов 