ESP8266 NodeMCU: Установка статического/фиксированного IP-адреса (Arduino IDE)
В этом руководстве показано, как установить статический/фиксированный IP-адрес для вашей платы ESP8266 NodeMCU. Если вы запускаете веб-сервер или Wi-Fi-клиент с ESP8266 и при каждой перезагрузке плата получает новый IP-адрес, вы можете следовать этому руководству, чтобы назначить статический/фиксированный IP-адрес.
Скетч для статического/фиксированного IP-адреса
Чтобы показать, как зафиксировать IP-адрес ESP8266, мы будем использовать код веб-сервера ESP8266 в качестве примера. К концу нашего объяснения вы сможете зафиксировать IP-адрес независимо от того, какой веб-сервер или Wi-Fi-проект вы создаёте.
Скопируйте приведённый ниже код в вашу Arduino IDE, но пока не загружайте его. Вам нужно внести некоторые изменения, чтобы он заработал для вас.
Примечание: если вы загрузите следующий скетч на плату ESP8266, он должен автоматически назначить фиксированный IP-адрес 192.168.1.184.
/*********
Rui Santos
Complete project details at https://RandomNerdTutorials.com/esp8266-nodemcu-static-fixed-ip-address-arduino/
*********/
// Load Wi-Fi library
#include <ESP8266WiFi.h>
// Replace with your network credentials
const char* ssid = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";
// Set web server port number to 80
WiFiServer server(80);
// Variable to store the HTTP request
String header;
// Auxiliar variables to store the current output state
String output5State = "off";
String output4State = "off";
// Assign output variables to GPIO pins
const int output5 = 5;
const int output4 = 4;
// Current time
unsigned long currentTime = millis();
// Previous time
unsigned long previousTime = 0;
// Define timeout time in milliseconds (example: 2000ms = 2s)
const long timeoutTime = 2000;
// Set your Static IP address
IPAddress local_IP(192, 168, 1, 184);
// Set your Gateway IP address
IPAddress gateway(192, 168, 1, 1);
IPAddress subnet(255, 255, 0, 0);
IPAddress primaryDNS(8, 8, 8, 8); //optional
IPAddress secondaryDNS(8, 8, 4, 4); //optional
void setup() {
Serial.begin(115200);
// Initialize the output variables as outputs
pinMode(output5, OUTPUT);
pinMode(output4, OUTPUT);
// Set outputs to LOW
digitalWrite(output5, LOW);
digitalWrite(output4, LOW);
// Configures static IP address
if (!WiFi.config(local_IP, gateway, subnet, primaryDNS, secondaryDNS)) {
Serial.println("STA Failed to configure");
}
// Connect to Wi-Fi network with SSID and password
Serial.print("Connecting to ");
Serial.println(ssid);
WiFi.begin(ssid, password);
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(".");
}
// Print local IP address and start web server
Serial.println("");
Serial.println("WiFi connected.");
Serial.println("IP address: ");
Serial.println(WiFi.localIP());
server.begin();
}
void loop(){
WiFiClient client = server.available(); // Listen for incoming clients
if (client) { // If a new client connects,
Serial.println("New Client."); // print a message out in the serial port
String currentLine = ""; // make a String to hold incoming data from the client
currentTime = millis();
previousTime = currentTime;
while (client.connected() && currentTime - previousTime <= timeoutTime) { // loop while the client's connected
currentTime = millis();
if (client.available()) { // if there's bytes to read from the client,
char c = client.read(); // read a byte, then
Serial.write(c); // print it out the serial monitor
header += c;
if (c == '\n') { // if the byte is a newline character
// if the current line is blank, you got two newline characters in a row.
// that's the end of the client HTTP request, so send a response:
if (currentLine.length() == 0) {
// HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
// and a content-type so the client knows what's coming, then a blank line:
client.println("HTTP/1.1 200 OK");
client.println("Content-type:text/html");
client.println("Connection: close");
client.println();
// turns the GPIOs on and off
if (header.indexOf("GET /5/on") >= 0) {
Serial.println("GPIO 5 on");
output5State = "on";
digitalWrite(output5, HIGH);
} else if (header.indexOf("GET /5/off") >= 0) {
Serial.println("GPIO 5 off");
output5State = "off";
digitalWrite(output5, LOW);
} else if (header.indexOf("GET /4/on") >= 0) {
Serial.println("GPIO 4 on");
output4State = "on";
digitalWrite(output4, HIGH);
} else if (header.indexOf("GET /4/off") >= 0) {
Serial.println("GPIO 4 off");
output4State = "off";
digitalWrite(output4, LOW);
}
// Display the HTML web page
client.println("<!DOCTYPE html><html>");
client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
client.println("<link rel=\"icon\" href=\"data:,\">");
// CSS to style the on/off buttons
// Feel free to change the background-color and font-size attributes to fit your preferences
client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
client.println(".button { background-color: #195B6A; border: none; color: white; padding: 16px 40px;");
client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
client.println(".button2 {background-color: #77878A;}</style></head>");
// Web Page Heading
client.println("<body><h1>ESP8266 Web Server</h1>");
// Display current state, and ON/OFF buttons for GPIO 5
client.println("<p>GPIO 5 - State " + output5State + "</p>");
// If the output5State is off, it displays the ON button
if (output5State=="off") {
client.println("<p><a href=\"/5/on\"><button class=\"button\">ON</button></a></p>");
} else {
client.println("<p><a href=\"/5/off\"><button class=\"button button2\">OFF</button></a></p>");
}
// Display current state, and ON/OFF buttons for GPIO 4
client.println("<p>GPIO 4 - State " + output4State + "</p>");
// If the output4State is off, it displays the ON button
if (output4State=="off") {
client.println("<p><a href=\"/4/on\"><button class=\"button\">ON</button></a></p>");
} else {
client.println("<p><a href=\"/4/off\"><button class=\"button button2\">OFF</button></a></p>");
}
client.println("</body></html>");
// The HTTP response ends with another blank line
client.println();
// Break out of the while loop
break;
} else { // if you got a newline, then clear currentLine
currentLine = "";
}
} else if (c != '\r') { // if you got anything else but a carriage return character,
currentLine += c; // add it to the end of the currentLine
}
}
}
// Clear the header variable
header = "";
// Close the connection
client.stop();
Serial.println("Client disconnected.");
Serial.println("");
}
}
Настройка сетевых данных
Вам нужно изменить следующие строки, указав свои сетевые данные: SSID и пароль.
// Replace with your network credentials
const char* ssid = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";
Установка статического IP-адреса ESP8266
Затем, вне функций setup() и loop(), вы определяете следующие переменные с вашим собственным статическим IP-адресом и соответствующим IP-адресом шлюза.
По умолчанию следующий код назначает IP-адрес 192.168.1.184, который работает со шлюзом 192.168.1.1.
// Set your Static IP address
IPAddress local_IP(192, 168, 1, 184);
// Set your Gateway IP address
IPAddress gateway(192, 168, 1, 1);
IPAddress subnet(255, 255, 0, 0);
IPAddress primaryDNS(8, 8, 8, 8); // optional
IPAddress secondaryDNS(8, 8, 4, 4); // optional
Важно: вам нужно использовать доступный IP-адрес в вашей локальной сети и соответствующий шлюз.
setup()
В setup() вам нужно вызвать метод WiFi.config() для назначения конфигурации вашему ESP8266.
// Configures static IP address
if (!WiFi.config(local_IP, gateway, subnet, primaryDNS, secondaryDNS)) {
Serial.println("STA Failed to configure");
}
Примечание: параметры primaryDNS и secondaryDNS являются необязательными, и вы можете их убрать.
Тестирование
После загрузки кода на плату откройте Serial Monitor Arduino IDE со скоростью передачи данных 115200, перезагрузите плату ESP8266, и ранее определённый IP-адрес должен быть назначен вашей плате.
Как видите, выводится IP-адрес 192.168.1.184.
Вы можете взять этот пример и добавить его во все свои Wi-Fi скетчи, чтобы назначить фиксированный IP-адрес вашему ESP8266.
Назначение IP-адреса через MAC-адрес
Если вы попытались назначить фиксированный IP-адрес ESP8266 с помощью предыдущего примера, и это не сработало, мы рекомендуем назначить IP-адрес непосредственно в настройках вашего маршрутизатора через MAC-адрес ESP8266.
Загрузите следующий код на плату ESP8266:
/*
Rui Santos & Sara Santos - Random Nerd Tutorials
Complete project details at https://RandomNerdTutorials.com/get-change-esp32-esp8266-mac-address-arduino/
Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files.
The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.
*/
#ifdef ESP32
#include <WiFi.h>
#include <esp_wifi.h>
#else
#include <ESP8266WiFi.h>
#endif
void setup(){
Serial.begin(115200);
Serial.print("ESP Board MAC Address: ");
#ifdef ESP32
WiFi.mode(WIFI_STA);
WiFi.STA.begin();
uint8_t baseMac[6];
esp_err_t ret = esp_wifi_get_mac(WIFI_IF_STA, baseMac);
if (ret == ESP_OK) {
Serial.printf("%02x:%02x:%02x:%02x:%02x:%02x\n",
baseMac[0], baseMac[1], baseMac[2],
baseMac[3], baseMac[4], baseMac[5]);
} else {
Serial.println("Failed to read MAC address");
}
#else
Serial.println(WiFi.macAddress());
#endif
}
void loop(){
}
В setup() он выводит MAC-адрес ESP8266 в Serial Monitor:
// Print ESP MAC Address
Serial.println("MAC address: ");
Serial.println(WiFi.macAddress());
В нашем случае MAC-адрес ESP8266 — B4:E6:2D:97:EE:F1. Скопируйте MAC-адрес, потому что он вам понадобится через мгновение.
Настройки маршрутизатора
Если вы войдёте на страницу администрирования вашего маршрутизатора, там должна быть страница/меню, где вы можете назначить IP-адрес сетевому устройству. Каждый маршрутизатор имеет разные меню и настройки. Поэтому мы не можем предоставить инструкции о том, как это сделать для всех доступных маршрутизаторов.
Мы рекомендуем загуглить «назначить IP-адрес по MAC-адресу» с указанием названия вашего маршрутизатора. Вы должны найти инструкции, которые покажут, как назначить IP по MAC-адресу для вашего конкретного маршрутизатора.
Таким образом, если вы перейдёте в меню конфигурации вашего маршрутизатора, вы сможете назначить желаемый IP-адрес MAC-адресу вашего ESP8266 (например, B4:E6:2D:97:EE:F1).
Заключение
После выполнения этого руководства вы должны быть в состоянии назначить фиксированный/статический IP-адрес вашему ESP8266. Если у вас ESP32, вы можете прочитать это руководство: Установка статического/фиксированного IP-адреса ESP32.
Надеемся, что это руководство было для вас полезным. Если вам нравится ESP8266, вам также могут понравиться:
Спасибо за чтение.